blob: 6c1f982ecc182483628a9054d62841476f5de644 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: twa022 <twa022 at gmail dot com>
_pkgname=xfdesktop
pkgname=${_pkgname}-devel
pkgver=4.19.6
pkgrel=1
pkgdesc="A desktop manager for Xfce (development release)"
arch=('i686' 'x86_64' 'aarch64' 'armv7h')
url="https://docs.xfce.org/xfce/xfdesktop/start"
license=('GPL2')
groups=('xfce4-devel')
depends=('thunar' 'garcon' 'hicolor-icon-theme' 'libxfce4windowing>=4.19.8' 'gtk-layer-shell' 'libyaml')
makedepends=('glib2-devel' 'meson')
conflicts=('xfce4-menueditor' "${_pkgname}")
provides=("${_pkgname}=${pkgver}")
replaces=('xfce4-menueditor')
options=('!libtool')
source=("https://archive.xfce.org/src/xfce/${_pkgname}/${pkgver%.*}/${_pkgname}-${pkgver}.tar.bz2")
sha256sums=('d52026c9e45fc669c4f373cf10b1f218327e818bb71f1eae3d1d10d9ec13c3a6')
build() {
local meson_options=(
-D x11=enabled
-D wayland=enabled
-D desktop-menu=enabled
-D tests=false
)
arch-meson "${_pkgname}-${pkgver}" build "${meson_options[@]}"
meson compile -C build
}
package() {
meson install -C build --destdir "$pkgdir"
}
|