PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
pkgname=xiguavideo-bin
_zhsname="西瓜视频"
pkgver=1.0.9
_electronversion=20
pkgrel=2
pkgdesc="XiGua Video use system-wide electron.西瓜视频Windows移植版,使用系统electron."
arch=("x86_64")
url="https://www.ixigua.com"
_dlurl="https://lf-xigua-pc.ixigua.com/obj/xigua-video-electron"
license=('LicenseRef-freeware')
provides=("${pkgname%-bin}")
conflicts=(
    "${pkgname%-bin}"
    "deepin-wine-${pkgname%-bin}"
)
depends=(
    "electron${_electronversion}-bin"
)
makedepends=(
    'gendesk'
    'asar'
    'npm'
)
noextract=("${pkgname%-bin}-${pkgver}.exe")
source=(
    "${pkgname%-bin}-${pkgver}.exe::${_dlurl}/6922326164589517070/releases/11463809/${pkgver}/win32/xigua-video-${pkgver}-default.exe"
    LICENSE.html
    "${pkgname%-bin}.sh"
)
sha256sums=('555761bb662ca4268c737e198937de1a3ba722b44707a6f5ce605445cfaa09c2'
            'bd956769c0d43acd95075a4a95c2ffe5b31f404b4c8675c481e95d0307e82bf1'
            'dc0c5ca385ad81a08315a91655c7c064b5bf110eada55e61265633ae198b39f8')
build() {
    sed -e "s|@electronversion@|${_electronversion}|" \
        -e "s|@appname@|${pkgname%-bin}|g" \
        -e "s|@runname@|app.asar|g" \
        -e "s|@options@||g" \
        -i "${srcdir}/${pkgname%-bin}.sh"
    gendesk -q -f -n --categories="AudioVideo" --name="${_zhsname}" --exec="${pkgname%-bin} %U"
    install -Dm755 -d "${srcdir}/tmp"
    bsdtar -xf "${srcdir}/${pkgname%-bin}-${pkgver}.exe" -C "${srcdir}/tmp"
    asar e "${srcdir}/tmp/resources/app.asar" "${srcdir}/app.asar.unpacked"
    cd "${srcdir}/app.asar.unpacked"
    sed '/tron-client/d' -i package.json
    npm install
    asar p "${srcdir}/app.asar.unpacked" "${srcdir}/app.asar"
}
package() {
    install -Dm755 "${srcdir}/${pkgname%-bin}.sh" "${pkgdir}/usr/bin/${pkgname%-bin}"
    install -Dm644 "${srcdir}/app.asar" -t "${pkgdir}/usr/lib/${pkgname%-bin}"
    install -Dm644 "${srcdir}/${pkgname%-bin}.desktop" -t "${pkgdir}/usr/share/applications"
    install -Dm644 "${srcdir}/app.asar.unpacked/dist/assets/logo.png" "${pkgdir}/usr/share/pixmaps/${pkgname%-bin}.png"
    install -Dm644 "${srcdir}/LICENSE.html" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}