blob: afe6c80722f1d659126e07dfed5e5293d726bd94 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
_basename="xf86-video-nouveau"
pkgname="${_basename//xf86/xlibre}"
pkgver=1.0.18.1
pkgrel=1
pkgdesc="Open Source 3D acceleration driver for nVidia cards"
arch=('aarch64' 'x86_64')
url="https://github.com/X11Libre/${_basename}"
license=('MIT')
depends=('glibc' 'libdrm' 'mesa' 'systemd-libs')
makedepends=('systemd' 'xlibre-server-devel' 'X-ABI-VIDEODRV_VERSION=28.0')
provides=("${_basename}")
conflicts=("${_basename}" 'xorg-server<21.1.1' 'X-ABI-VIDEODRV_VERSION<28' 'X-ABI-VIDEODRV_VERSION>=29')
groups=('xlibre-drivers')
_pkgsrc="${_basename}-xlibre-${_basename}-${pkgver}"
source=("${_pkgsrc}.tar.gz::${url}/archive/refs/tags/xlibre-${_basename}-${pkgver}.tar.gz")
b2sums=('7fec1558831d7f4669aa8f5706287e83b4280b8b736fdbe66cba6185ece46ca2fc84189f5a9d5d0cb4dba8199dc98216eaf36b7826bb4214e93ad6c22abb32fe')
build() {
# Since pacman 5.0.2-2, hardened flags are now enabled in makepkg.conf
# With them, modules fail to load with undefined symbol.
# See https://bugs.archlinux.org/task/55102 / https://bugs.archlinux.org/task/54845
export CFLAGS="${CFLAGS/-fno-plt}"
export CXXFLAGS="${CXXFLAGS/-fno-plt}"
export LDFLAGS="${LDFLAGS/-Wl,-z,now}"
local configure_options=(
--prefix='/usr'
)
cd "${srcdir}/${_pkgsrc}"
autoreconf -vfi
./configure "${configure_options[@]}"
make
}
package() {
cd "${srcdir}/${_pkgsrc}"
make DESTDIR="${pkgdir}" install
# install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
|