blob: 4c122921e3ade87b2f41ca2c1f17f6f401805906 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Andy B. <brofi.archlinux at gmail dot com>
pkgname=xmobar-alsa
pkgver=0.31
pkgrel=1
pkgdesc="A Minimalistic Text Based Status Bar compiled with ALSA"
url="https://hackage.haskell.org/package/xmobar"
license=('BSD')
arch=('i686' 'x86_64')
conflicts=('xmobar')
depends=('haskell-alsa-core>=0.5.0' 'haskell-alsa-mixer>=0.3.0' 'libxft'
'libxinerama' 'libxrandr' 'libxpm' 'ghc-libs' 'haskell-x11'
'haskell-x11-xft' 'haskell-utf8-string' 'haskell-network-uri'
'haskell-hinotify' 'haskell-stm' 'haskell-parsec'
'haskell-parsec-numbers' 'haskell-mtl' 'haskell-regex-base'
'haskell-regex-compat' 'haskell-http' 'haskell-dbus' 'haskell-libmpd'
'haskell-iwlib' 'wireless_tools' 'haskell-text' 'haskell-async'
'haskell-extensible-exceptions' 'haskell-http-conduit')
makedepends=('ghc')
source=(https://github.com/jaor/xmobar/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
sha512sums=('b0afe21f398a16a2e9d6e94ecb643fc5a259e1f60504ce50acd90ae31ae2e14d0925afb66f9593ff2a9bb016e39ab612027e836ece8ede665c66badac3386d01')
prepare() {
cd xmobar-$pkgver
sed -i -e 's/==.*0.3/== 0.4/' -e 's/< *4.12/<5/' -e 's/< *2.5/<3/' xmobar.cabal
}
build() {
cd xmobar-$pkgver
runhaskell setup configure -O \
--enable-shared \
--prefix=/usr \
--enable-executable-dynamic \
--disable-library-vanilla \
--flags="with_utf8 with_xft with_iwlib with_xpm with_inotify with_mpd with_dbus with_mpris with_alsa"
runhaskell setup build
}
package() {
cd xmobar-$pkgver
runhaskell setup copy --destdir="$pkgdir"
install -Dm 644 license "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|