PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# $Id$

pkgname=xscreensaver-xmatrix-color
pkgver=5.42
pkgrel=1
pkgdesc="Screen saver and locker for the X Window System, modified xmatrix with variable color."
arch=('i686' 'x86_64')
url="http://www.jwz.org/xscreensaver/"
license=('BSD')
depends=('libglade' 'libxmu' 'glu' 'xorg-appres' 'perl-libwww')
makedepends=('bc' 'intltool' 'libxpm')
optdepends=('gdm: for login manager support')
conflicts=('xscreensaver')
provides=('xscreensaver')
backup=('etc/pam.d/xscreensaver')
source=(http://www.jwz.org/xscreensaver/${pkgname%%-*}-${pkgver}.tar.gz
	xscreensaver-add-electricsheep.diff
	xmatrix-color.diff
	fontglide.c.diff
	LICENSE)
sha1sums=('b8eb08e258a70924aa0e644e4930164baf505ee6'
          'e8dc57b6471fb3867ee099304ac6bf628351cb98'
          'faca46b814a8791dfe3619e755089ecb88ddf71c'
          '649c268c0afbb955eb0194a840ab46359f27c94b'
          'bf8995d86609cdab678ca277ae685407f82691db')

prepare() {
  cd ${pkgname%%-*}-${pkgver}
  patch -p0 -i "${srcdir}/xscreensaver-add-electricsheep.diff"
  patch -b -p0 -i "${srcdir}/xmatrix-color.diff"
  patch -b -p0 -i "${srcdir}/fontglide.c.diff"
}

build() {
  cd ${pkgname%%-*}-${pkgver}
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --libexecdir=/usr/lib --with-x-app-defaults=/usr/share/X11/app-defaults \
    --with-pam --with-login-manager --with-gtk --with-gl \
    --without-gle --with-pixbuf --with-jpeg
  make
}

package() {
  cd ${pkgname%%-*}-${pkgver}
  install -d "${pkgdir}/etc/pam.d"
  make install_prefix="${pkgdir}" install
  install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname%%-*}/LICENSE"
  chmod 755 "${pkgdir}/usr/bin/xscreensaver"
  echo "NotShowIn=KDE;GNOME;" >> "${pkgdir}/usr/share/applications/xscreensaver-properties.desktop"
}