summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1363d8f4f60fc4646df44de8555588b38d9ec340 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
# Maintainer: Baltazár Radics <baltazar.radics@gmail.com>

_target=xtensa-esp32-elf
_upstream_ver=esp-2021r2
_upstream_name=newlib-esp32
pkgname=$_target-newlib
pkgver=3.3.0.${_upstream_ver#esp-}
pkgrel=1
pkgdesc='A C standard library implementation intended for use on embedded systems (xtensa esp32 bare metal)'
arch=(x86_64)
url='https://github.com/espressif/newlib-esp32'
license=(GPL)
makedepends=($_target-gcc)
options=(!emptydirs !strip)
source=("$_upstream_name-$_upstream_ver.tar.gz::https://codeload.github.com/espressif/$_upstream_name/tar.gz/$_upstream_ver")
sha256sums=('dae87a0dd10cd4f107980a93cd458940ae02d3e03efdb4d3489b9fbaca9f478e')

build() {
	rm -rf build-{newlib,nano}
	mkdir build-{newlib,nano}

	# espressif's crosstool-ng:
	# 	CC_FOR_BUILD='x86_64-build_pc-linux-gnu-gcc'
	# 	CFLAGS_FOR_TARGET='  -mlongcalls '
	# 	AR_FOR_TARGET='./.build/xtensa-esp32-elf/buildtools/bin/xtensa-esp32-elf-gcc-ar'
	# 	RANLIB_FOR_TARGET='./.build/xtensa-esp32-elf/buildtools/bin/xtensa-esp32-elf-gcc-ranlib'
	# 	'/usr/bin/bash'
	# 	'./.build/xtensa-esp32-elf/src/newlib/configure'
	# 		'--host=x86_64-build_pc-linux-gnu'
	# 		'--target=xtensa-esp32-elf'
	# 		'--prefix=./builds/xtensa-esp32-elf'
	# 		'--enable-newlib-io-float'
	# 		'--disable-newlib-io-long-double'
	# 		'--disable-newlib-supplied-syscalls'
	# 		'--enable-newlib-io-pos-args'
	# 		'--enable-newlib-io-c99-formats'
	# 		'--enable-newlib-io-long-long'
	# 		'--disable-newlib-register-fini'
	# 		'--disable-newlib-nano-malloc'
	# 		'--disable-newlib-nano-formatted-io'
	# 		'--enable-newlib-atexit-dynamic-alloc'
	# 		'--disable-newlib-global-atexit'
	# 		'--disable-lite-exit'
	# 		'--enable-newlib-reent-small'
	# 		'--enable-newlib-multithread'
	# 		'--enable-newlib-wide-orient'
	# 		'--enable-newlib-unbuf-stream-opt'
	# 		'--enable-target-optspace'
	# 		'--enable-newlib-long-time_t'
	# 		'--enable-newlib-nano-malloc'

	export CFLAGS_FOR_TARGET='-g -O2 -ffunction-sections -fdata-sections -mlongcalls'
	cd "$srcdir"/build-newlib
	../$_upstream_name-$_upstream_ver/configure \
		--target=$_target \
		--prefix=/usr \
		--enable-newlib-io-float \
		--disable-newlib-io-long-double \
		--disable-newlib-supplied-syscalls \
		--enable-newlib-io-pos-args \
		--enable-newlib-io-c99-formats \
		--enable-newlib-io-long-long \
		--disable-newlib-register-fini \
		--disable-newlib-nano-malloc \
		--disable-newlib-nano-formatted-io \
		--enable-newlib-atexit-dynamic-alloc \
		--disable-newlib-global-atexit \
		--disable-lite-exit \
		--enable-newlib-reent-small \
		--enable-newlib-multithread \
		--enable-newlib-wide-orient \
		--enable-newlib-unbuf-stream-opt \
		--enable-target-optspace \
		--enable-newlib-long-time_t \
		--enable-newlib-nano-malloc
	make

	# espressif's crosstool-ng:
	# 	CC_FOR_BUILD='x86_64-build_pc-linux-gnu-gcc'
	# 	CFLAGS_FOR_TARGET='  -mlongcalls '
	# 	AR_FOR_TARGET='./.build/xtensa-esp32-elf/buildtools/bin/xtensa-esp32-elf-gcc-ar'
	# 	RANLIB_FOR_TARGET='./.build/xtensa-esp32-elf/buildtools/bin/xtensa-esp32-elf-gcc-ranlib'
	# 	'/usr/bin/bash'
	# 	'./.build/xtensa-esp32-elf/src/newlib/configure'
	# 		'--host=x86_64-build_pc-linux-gnu'
	# 		'--target=xtensa-esp32-elf'
	# 		'--prefix=./builds/xtensa-esp32-elf'
	# 		'--with-newlib'
	# 		'--enable-multilib'
	# 		'--disable-newlib-io-c99-formats'
	# 		'--disable-newlib-supplied-syscalls'
	# 		'--enable-newlib-nano-formatted-io'
	# 		'--enable-newlib-reent-small'
	# 		'--enable-target-optspace'
	# 		'--enable-newlib-long-time_t'
	# 		'--enable-newlib-nano-malloc'

	export CFLAGS_FOR_TARGET='-g -Os -ffunction-sections -fdata-sections -mlongcalls'
	cd "$srcdir"/build-nano
	../$_upstream_name-$_upstream_ver/configure \
		--target=$_target \
		--prefix=/usr \
		--with-newlib \
		--enable-multilib \
		--disable-newlib-io-c99-formats \
		--disable-newlib-supplied-syscalls \
		--enable-newlib-nano-formatted-io \
		--enable-newlib-reent-small \
		--enable-target-optspace \
		--enable-newlib-long-time_t \
		--enable-newlib-nano-malloc
	make
}

package() {
	cd "$srcdir"/build-nano
	make DESTDIR="$pkgdir" install -j1
	find "$pkgdir" -regex ".*/lib\(c\|g\|rdimon\)\.a" -exec rename .a _nano.a '{}' \;
	install -d "$pkgdir"/usr/$_target/include/newlib-nano
	install -m644 -t "$pkgdir"/usr/$_target/include/newlib-nano "$pkgdir"/usr/$_target/include/newlib.h

	cd "$srcdir"/build-newlib
	make DESTDIR="$pkgdir" install -j1

	find "$pkgdir"/usr/$_target/lib \( -name "*.a" -or -name "*.o" \) -exec $_target-objcopy -R .comment -R .note -R .debug_info -R .debug_aranges -R .debug_pubnames -R .debug_pubtypes -R .debug_abbrev -R .debug_line -R .debug_str -R .debug_ranges -R .debug_loc '{}' \;

	install -d "$pkgdir"/usr/share/licenses/$pkgname/
	install -m644 -t "$pkgdir"/usr/share/licenses/$pkgname/ "$srcdir"/$_upstream_name-$_upstream_ver/COPYING*
}