summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 865884dccc6bb1b40653fea347100adcf9a61ac2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
# Maintainer: spider-mario <spidermario@free.fr>
pkgname=xvc-git
pkgver=v1.0.r7.3e1db91
pkgrel=1
pkgdesc="Modern software-defined video compression format"
arch=('x86_64')
url="https://xvc.io/"
license=('custom')
depends=('gcc-libs')
makedepends=('git' 'cmake')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/divideon/xvc.git')
sha512sums=('SKIP')

pkgver() {
	cd "$srcdir"/xvc
	printf "%s" "$(git describe --long --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}

build() {
	mkdir -p build
	cd build
	cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr "$srcdir"/xvc
	make
}

check() {
	cd build
	make test
}

package() {
	cd build
	make DESTDIR="$pkgdir/" install
	install -Dm644 "$srcdir"/xvc/LICENSE "$pkgdir"/usr/share/licenses/"$pkgname"/LICENSE
}