PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: Tomaz Canabrava <tcanabrava@archlinux.org>

pkgname=xwaylandvideobridge
pkgver=0.4.0
pkgrel=3
pkgdesc='Utility to allow streaming Wayland windows to X applications'
arch=(x86_64)
url='https://invent.kde.org/system/xwaylandvideobridge'
license=(LGPL GPL)
depends=(
    glibc
    gcc-libs
    qt6-base
    qt6-declarative
    kcoreaddons
    ki18n
    kwindowsystem
    kpipewire
    kstatusnotifieritem
    libxcb
)

makedepends=(
    extra-cmake-modules
    kdoctools
    knotifications
)

source=(https://download.kde.org/stable/xwaylandvideobridge/$pkgname-$pkgver.tar.xz{,.sig})

sha256sums=('ea72ac7b2a67578e9994dcb0619602ead3097a46fb9336661da200e63927ebe6'
            'SKIP')

validpgpkeys=(
  E0A3EB202F8E57528E13E72FD7574483BB57B18D # Jonathan Esk-Riddell
)

prepare() {
  cd "$pkgname-$pkgver"

  sed -i '/find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS Quick DBus)/a\
if (QT_MAJOR_VERSION STREQUAL "6")\
    find_package(Qt6 REQUIRED COMPONENTS GuiPrivate)\
endif()' CMakeLists.txt
}

build() {
  cmake -B build -S $pkgname-$pkgver \
    -DBUILD_TESTING=OFF \
    -DQT_MAJOR_VERSION=6
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}