PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Maintainer: Dunky <braxtinmoss13@gmail.com>
# Previous Maintainer: DawfukFR <dawfukfr@gmail.com>
# Contact: (Telegram: @Dawfuk)

pkgname=xwaylandvideobridge-git
_pkgname=xwaylandvideobridge
pkgver=0.4.0_r243.g1a8d5af
pkgrel=1
pkgdesc="A tool to make it easy to stream Wayland windows and screens to Xwayland applications that don't have native pipewire support"
arch=(x86_64)
url='https://invent.kde.org/system/xwaylandvideobridge'
license=('GPL-2.0-or-later')
provides=(xwaylandvideobridge)
depends=(
  glibc
  gcc-libs
  qt6-base
  qt6-declarative
  kcrash
  kcoreaddons
  ki18n
  kwindowsystem
  kpipewire
  kstatusnotifieritem
  libxcb
)
makedepends=(
  extra-cmake-modules
  kdoctools
  knotifications
  git
)
conflicts=(xwaylandvideobridge)
source=("git+https://invent.kde.org/system/xwaylandvideobridge.git")
sha256sums=('SKIP')

# Dynamically update Package Version from Git
pkgver() {
  cd ${pkgname%-git}
  _ver="$(grep -m1 'set(PROJECT_VERSION' CMakeLists.txt | cut -d '"' -f2 | tr - .)"
  echo "${_ver}_r$(git rev-list --count HEAD).g$(git rev-parse --short HEAD)"
}

build() {
  cmake -B build -S ${pkgname%-git} \
    -DBUILD_TESTING=OFF \
    -DQT_MAJOR_VERSION=6
  cmake --build build
}

# Build Package
package() {
  DESTDIR="$pkgdir" cmake --install build
  # Install license (LICENSES/ dir follows REUSE spec)
  install -Dm644 "${pkgname%-git}/LICENSES/GPL-2.0-or-later.txt" \
    "$pkgdir/usr/share/licenses/$pkgname/GPL-2.0-or-later.txt"
}