blob: 0c4bddea49fedfbec2b320cf0e861dc4c8e69d9b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Jonas Geiler <aur@jonasgeiler.com>
# Maintainer: SoftExpert <softexpert at gmail dot com>
pkgname=yaak-bin
# renovate: datasource=github-releases depName=getyaak/app
pkgver=2024.13.0
pkgrel=1
pkgdesc='Simple and intuitive API client for calling REST, GraphQL, and gRPC APIs (Pre-compiled version)'
arch=(x86_64)
url='https://yaak.app/'
license=(MIT)
depends=(
# As reported by namcap
cairo
gcc-libs
gdk-pixbuf2
glib2
glibc
gtk3
hicolor-icon-theme
libsoup3
pango
webkit2gtk-4.1
)
provides=(yaak yaak-app)
conflicts=(
yaak
yaak-app-beta
yaak-appimage
yaak-git
)
replaces=(yaak-app)
options=(
!strip # Stripping symbols would break the binary
!emptydirs # Remove empty directories from package because why not
)
source_x86_64=(
"${pkgname}-${pkgver}.deb::https://github.com/mountain-loop/yaak/releases/download/v${pkgver}/yaak_${pkgver}_amd64.deb"
"${pkgname}-${pkgver}.LICENSE::https://raw.githubusercontent.com/mountain-loop/yaak/refs/tags/v${pkgver}/LICENSE"
)
b2sums_x86_64=('ef39dda8b3b8cb9473f8223e752365f5e4c7353bcc56ba29b8c3236534e7c93d79b41e0cc2fd46e2d7b7c4f2e021d7d594235b8a8936f9cd44c65565c8769452'
'011fb406bfe4a8944efbae1f9cfa420fe421f1de3ae628802548676a1fe1318850a5f98c60cd29899efe3946dec329b6607f04917e966808f62f9e4ecaaea13b')
prepare() {
bsdtar -xf "${srcdir}/data.tar.gz" -C "${srcdir}/"
}
build() {
sed -e 's|Name=yaak|Name=Yaak|' \
-e '$aGenericName=API Client' \
-i "${srcdir}/usr/share/applications/yaak.desktop"
}
package() {
cp -a \
"${srcdir}/usr/" \
"${pkgdir}/usr/"
install -Dm644 \
"${srcdir}/${pkgname}-${pkgver}.LICENSE" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|