blob: eb654b40b40da6c9274ed0619848e1a52e711903 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: dmitrysvd
pkgname=yandex-music
pkgver=5.91.1
pkgrel=1
pkgdesc="Official Yandex Music App for Linux"
arch=('x86_64')
url="https://music.yandex.ru/download/"
license=('unknown')
depends=(
gtk3
libnotify
nss
libxss
libxtst
xdg-utils
at-spi2-core
util-linux-libs
libsecret
)
optdepends=(
libappindicator-gtk3
)
options=('!strip')
source=("https://music-desktop-application.s3.yandex.net/stable/Yandex_Music_amd64_${pkgver}.deb")
sha256sums=('065f50d865512677039c226a6ce77ab0b10a35527ad56ac988913dc266e43af4')
package() {
tar -xf data.tar.xz --directory "${pkgdir}"
# Remove Cyrillic from the path
mv "${pkgdir}/opt/Яндекс Музыка" "${pkgdir}/opt/yandex-music"
sed -i 's|/opt/Яндекс Музыка|/opt/yandex-music|g' "${pkgdir}/usr/share/applications/yandexmusic.desktop"
# Fix menu category
sed -i 's|Categories=Audio;|Categories=AudioVideo;Audio;|g' "${pkgdir}/usr/share/applications/yandexmusic.desktop"
# Fix GTK version error for Gnome users
sed -i 's|Exec="/opt/yandex-music/yandexmusic"|Exec="/opt/yandex-music/yandexmusic" --gtk-version=3|' "${pkgdir}/usr/share/applications/yandexmusic.desktop"
}
|