blob: a2d99b9422ee3801c9841cedcf3cd56de43a3d2e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Andrew O'Neill <andrew at haunted dot sh>
# Contributor: Pablo Lezaeta <prflr88@gmail.com>
pkgname=yash
pkgver=2.58.1
pkgrel=1
pkgdesc='Yet Another SHell is a POSIX-compliant command line shell'
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url='https://magicant.github.io/yash/'
license=('GPL-2.0-only')
depends=('ncurses')
makedepends=('asciidoc' 'ed')
options=('lto')
install="${pkgname}.install"
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/magicant/${pkgname}/archive/refs/tags/${pkgver}.tar.gz"
"${pkgname}.install")
sha256sums=('0255c0cad475b88ad32f4247837e77b5a4999e41c268f08107c094a16eb57f53'
'c66c7a4b9da4416082ea57bbec0ce0c2bbc13af340ceb1241b4a4897d8944531')
build() {
cd "${pkgname}-${pkgver}"
./configure \
--prefix=/usr \
--enable-array \
--enable-dirstack \
--enable-double-bracket \
--enable-help \
--enable-history \
--enable-lineedit \
--enable-nls \
--enable-printf \
--enable-socket \
--enable-test \
--enable-ulimit
make
}
check() {
cd "${pkgname}-${pkgver}"
make check
}
package() {
cd "${pkgname}-${pkgver}"
make install DESTDIR="${pkgdir}"
install -Dm0644 doc/*.{css,html} -t "${pkgdir}/usr/share/doc/${pkgname}/"
install -Dm0644 doc/ja/*.{css,html} -t "${pkgdir}/usr/share/doc/${pkgname}/ja/"
}
|