blob: 50841af4786b4626432815e565225cef1b012528 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Maintainer: Caleb Maclennan <caleb@alerque.com>
pkgname=youki
pkgver=0.3.2
pkgrel=2
pkgdesc='A container runtime written in Rust'
arch=('x86_64')
url='https://containers.github.io/youki'
license=('Apache')
depends=('gcc-libs' 'libseccomp' 'dbus')
makedepends=('rust' 'git' 'dbus-glib' 'systemd')
optdepends=(
'docker: run via docker'
'podman: run via podman'
)
options=('!lto')
source=("git+https://github.com/containers/youki.git#tag=v$pkgver")
sha256sums=('f21deb7be283aa18bcd5433fb6c4b3c1b6a514bb6bc541a86afc0af1d4159751')
prepare() {
cd youki
# create directory for build artifacts
mkdir build
# v0.3.2 lock file is out of sync
cargo update
# download dependencies
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd youki
cargo build --frozen --release --bin youki
# generate shell completions
for shell in bash fish zsh; do
./target/release/youki completion --shell "$shell" > "build/$shell-completion"
done
}
#check() {
# cd youki
#
# cargo test --frozen
#}
package() {
cd youki
install -vDm755 -t "$pkgdir/usr/bin" target/release/youki
# shell completions
install -vDm644 build/bash-completion "$pkgdir/usr/share/bash-completion/completions/youki"
install -vDm644 build/fish-completion "$pkgdir/usr/share/fish/vendor_completions.d/youki.fish"
install -vDm644 build/zsh-completion "$pkgdir/usr/share/zsh/site-functions/_youki"
}
|