blob: 2b89749b24c25efb7066ebf09496bfde48a32c55 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: tarball <bootlctl@gmail.com>
pkgname=youtube-dl-nightly
pkgver=2024.08.07
pkgrel=1
pkgdesc='A command-line program to download videos from YouTube.com and a few more sites'
arch=('any')
url='https://ytdl-org.github.io/youtube-dl'
license=('Unlicense')
depends=('python')
provides=('youtube-dl')
conflicts=('youtube-dl')
makedepends=('python-setuptools')
optdepends=('ffmpeg: for video post-processing'
'rtmpdump: for rtmp streams support'
'atomicparsley: for embedding thumbnails into m4a files'
'python-pycryptodome: for hlsnative downloader'
'python-pycryptodomex: for ivi extractor'
'python-brotli: support for the Brotli compression format'
'aria2: alternative parallel downloader')
source=("https://github.com/ytdl-org/ytdl-nightly/releases/download/${pkgver}/youtube-dl-${pkgver}.tar.gz")
sha256sums=('ba3a469eb6d7887442b427e4b76f87f2d8115be83c4e7a49f36befd3c4004169')
prepare() {
cd youtube-dl
sed -i 's|etc/bash_completion.d|share/bash-completion/completions|' setup.py
sed -i 's|etc/fish/completions|share/fish/vendor_completions.d|' setup.py
}
build() {
cd youtube-dl
python setup.py build
}
package() {
cd youtube-dl
python setup.py install --root="${pkgdir}/" --optimize=1 --skip-build
mv "${pkgdir}/usr/share/bash-completion/completions/youtube-dl.bash-completion" \
"${pkgdir}/usr/share/bash-completion/completions/youtube-dl"
install -Dm644 youtube-dl.zsh "${pkgdir}/usr/share/zsh/site-functions/_youtube-dl"
}
|