blob: 68405f1a3e8c3373de86e4088292d39dfdb9dadf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Nguyen Hoang Ky <nhktmdzhg at gmail dot com>
_pkgname=zalo
pkgname=zalo-macos
replaces=(zalo-unofficial-git)
provides=(zalo-unofficial-git)
conflicts=(zalo-unofficial-git)
pkgver=25.4.2
pkgrel=2
pkgdesc="Unofficial Zalo client for Linux, port from MacOS version"
arch=('x86_64')
url="https://zalo.me"
license=('custom')
depends=(
'python'
'python-pillow'
'python-pystray'
'electron22-bin'
)
makedepends=(
'7zip'
'asar'
)
source=(
"zalo.dmg::https://res-download-pc-te-vnso-pt-34.zadn.vn/mac/ZaloSetup-universal-${pkgver}.dmg"
"zalo.desktop"
"zalo_py"
"Zalo.png"
"LICENSE.html::https://zalo.vn/dieukhoan"
)
noextract=("zalo.dmg")
sha256sums=('1d41aaa3c20a8e8410425d299fadcaababaa6174f66f719291e36c381afb54b5'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
)
options=('!strip' '!purge')
prepare() {
local archive_path="Zalo ${pkgver}-universal/Zalo.app/Contents/Resources"
mkdir -p "${srcdir}/build"
for file in app-update.yml app.asar icon.icns app.asar.unpacked; do
7z x -y "${srcdir}/zalo.dmg" "$archive_path/$file"
mv "$archive_path/$file" "${srcdir}/build/"
done
rm -rf "Zalo ${pkgver}-universal"
}
build() {
asar e "${srcdir}/build/app.asar" "${srcdir}/build/app"
rm "${srcdir}/build/app.asar"
}
package() {
install -d "${pkgdir}/opt/${_pkgname}"
cp -r "${srcdir}/build/app" "${pkgdir}/opt/${_pkgname}/"
cp -r "${srcdir}/build/icon.icns" "${pkgdir}/opt/${_pkgname}/"
cp -r "${srcdir}/build/app-update.yml" "${pkgdir}/opt/${_pkgname}/"
install -Dm644 "${srcdir}/Zalo.png" "${pkgdir}/opt/${_pkgname}/icon.png"
install -Dm644 "${srcdir}/zalo.desktop" "${pkgdir}/usr/share/applications/zalo.desktop"
install -Dm755 "${srcdir}/zalo_py" "${pkgdir}/usr/bin/zalo"
install -Dm644 "${srcdir}/LICENSE.html" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE.html"
}
|