summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 26c56490bfbefb7f170a6c25b68bb55c7059054c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Moritz Lipp <mlq@pwmt.org>

pkgname=zathura-pdf-poppler-git
pkgrel=1
pkgver=0.3.0.1.gbc6e1ca
pkgdesc="PDF support for zathura by using the poppler rendering library"
arch=('i686' 'x86_64')
url="http://pwmt.org/projects/zathura-pdf-poppler"
license=('custom')
depends=('zathura-git' 'poppler-glib')
makedepends=('git' 'python-sphinx' 'intltool' 'meson')
checkdepends=('check')
conflicts=('zathura-pdf-mupdf' 'zathura-pdf-mupdf-git' 'zathura-pdf-poppler')
provides=('zathura-pdf-poppler-git' 'zathura-pdf-poppler')
source=('zathura-pdf-poppler::git+https://git.pwmt.org/pwmt/zathura-pdf-poppler.git#branch=develop')
md5sums=('SKIP')
_gitname=zathura-pdf-poppler

prepare() {
  mkdir -p build
}

build() {
  cd build
  meson --prefix=/usr --buildtype=release $srcdir/$_gitname
  ninja
}

check() {
  cd build
  ninja test
}

package() {
  cd build
  DESTDIR="$pkgdir/" ninja install
}

pkgver() {
  cd "$_gitname"
  local ver="$(git describe --long)"
  printf "%s" "${ver//-/.}"
}

# vim:set ts=2 sw=2 et: