blob: 7a1616dc57a1e5fc9d4f06eb08f6699482fb4ce0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Maintainer: DLLCoolJ <archcloudlabs[at]gmail[dot]com>
# Contributor: KokaKiwi <kokakiwi+aur [at] kokakiwi [dot] net>
# Contributor: Nick Skelsey <nskelsey@gmail.com>
pkgname=zeek
pkgver=6.1.1
pkgrel=1
pkgdesc="A network analysis framework"
arch=('x86_64')
url="https://zeek.org"
license=('BSD')
depends=(zlib libpcap bash libmaxminddb python)
makedepends=(cmake swig bison flex openssl geoip gperftools shadow)
optdepends=(
'python-semantic-version: zeekpkg'
)
source=("https://download.zeek.org/zeek-$pkgver.tar.gz"{,.asc}
zeek.tmpfiles.conf)
sha256sums=('8fc565e9573f5aed49a435745285e42dc10f5234549efc1502af7544f68337e5'
'93ec03acd9dc47d5dd4449779914de7276f04001965988063f17ee1da1ac4eef'
'af5b7e14caae88122d0e6dd29539ae77ed3388c70a12ea0ed73c9a3f6de16d91')
b2sums=('b546762e1ab55097f44313d3dd9b5df6be4e9221923416fb3f8c677cc6e3e7b35c1fa3a9bc2e5312bf4b09db42c86c641edffaae7fec850a950e74b57590d591'
'd52b0f22f5204d3e15489e1be5a169a75fed38c9c1be576e2885c709336c8d5e491d35a341ab471f5a6bee8a87e6318ca79b7f5bb8fc38e5ec41faa411870786'
'df5e4479c89cc2b0764e26e35bdcbcd7d00b131d7f4cd35c336e734ae334a40a2142285a2c8ea9db8961a34bb4d2799ba89505ab3e3881a16792c7e804ef1d73'
)
validpgpkeys=(
962FD2187ED5A1DD82FC478A33F15EAEF8CB8019 # The Zeek Team <info@zeek.org>
)
build() {
cmake -B build -S "zeek-$pkgver" \
-D CMAKE_INSTALL_PREFIX=/usr \
-D ZEEK_PYTHON_PREFIX:PATH=/usr \
-D ZEEK_ETC_INSTALL_DIR:PATH=/etc \
-D ZEEK_STATE_DIR:PATH=/var/lib \
-D ZEEK_SPOOL_DIR:PATH=/var/spool \
-D ZEEK_LOG_DIR:PATH=/var/log/zeek \
-D BINARY_PACKAGING_MODE=ON \
-D BUILD_SHARED_LIBS=ON \
-D BUILD_STATIC_BINPAC=ON \
-D BROKER_DISABLE_TESTS=ON \
-D BROKER_DISABLE_DOC_EXAMPLES=ON \
-D INSTALL_AUX_TOOLS=ON \
-D INSTALL_ZEEK_ARCHIVER=ON \
-D INSTALL_ZKG=ON
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
rm -rf "$pkgdir/usr/var"
install -dm0755 "$pkgdir/var/lib/zkg"
for exename in bro bro-config bro-cut; do
ln -sf zeek "$pkgdir/usr/bin/$exename"
done
install -Dm0644 zeek.tmpfiles.conf "$pkgdir/usr/lib/tmpfiles.d/zeek.conf"
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname" \
"zeek-$pkgver"/COPYING{,-3rdparty}
}
|