blob: f82585fec055a00eeeef71c63afa9e3d131c9969 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
pkgname=zelda-nsq
pkgver=1.8
pkgrel=2
pkgdesc="'Zelda: Navi's Quest is a fan-made Zelda Game (english version)"
url="http://www.zeldaroth.fr/"
arch=('i686' 'x86_64')
license=('unknown')
depends=('sdl_gfx' 'sdl_mixer' 'sdl_image')
makedepends=("imagemagick")
conflicts=("$pkgname-fr")
source=("http://www.zeldaroth.fr/us/files/NSQ/Linux/ZeldaNSQ_US-src-linux.zip"
"$pkgname-datafolders.patch"
"$pkgname.desktop")
sha256sums=('e33cf28ad8f160e94e24f4273b1546f64fc8f10f5d46c7ecc9e4b3e5edb2f571'
'3b445f73fd2be4218b446dc510551d09629932140682682eec599d3a076f84c7'
'b0bb398ba03e2a8bc1d66d720b9ec2d962247c7ef0725b2a60ff716fa9ca8ef0')
prepare() {
# use user's $HOME for saves and load data from /usr/share/zelda-nsq
patch -Np0 < $pkgname-datafolders.patch
# set our $CFLAGS
cd ZeldaNSQ_US-src-linux
sed 's|CFLAGS =.*|CFLAGS += -I/usr/include/SDL|' -i makefile
# create an icon
convert data/images/title/titre.png -thumbnail '48x48' -background transparent \
-gravity center -extent 48x48 "$srcdir"/$pkgname.png
}
build() {
make -C ZeldaNSQ_US-src-linux release
}
package() {
cd ZeldaNSQ_US-src-linux
install -Dm755 bin/Release/ZeldaNSQ "$pkgdir"/usr/bin/$pkgname
install -d "$pkgdir"/usr/share
cp -rup data "$pkgdir"/usr/share/$pkgname
install -Dm644 "$srcdir/"$pkgname.png "$pkgdir"/usr/share/pixmaps/$pkgname.png
install -Dm644 "$srcdir/"$pkgname.desktop "$pkgdir"/usr/share/applications/$pkgname.desktop
}
|