PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer : silverhikari <kerrickethan@gmail.com>
# Contributor: Elijah Gregg <lovetocode999@ctrl-c.club>
# Contributor: Alexandros Theodotou <alex@zrythm.org>
pkgname=zrythm-git
pkgver=1.0.0.r0.g8b3de7881
pkgrel=1
epoch=3
pkgdesc='a highly automated and intuitive digital audio workstation'
arch=('x86_64' 'i686')
url="https://www.zrythm.org"
license=('custom:Zrythm License')
depends=('lilv' 'libx11' 'libsndfile' 'libsamplerate' 'alsa-lib' 'fftw'
         'suil' 'breeze-icons' 'lv2' 'rubberband' 'python-sphinx-furo' 'python-sphinx-copybutton' 'python-sphinxcontrib-svg2pdfconverter'
         'xxhash' 'vamp-plugin-sdk' 'carla-git' 'gtk4' 'guile' 'libadwaita' 'gtksourceview5' 'pcre' 'libpulse' 'curl' 'libaudec' 'json-glib' 'libcyaml' 'reproc' 'libpanel' 'boost' 'lsp-dsp-lib' 'zstd' 'zix' 'yyjson' 'magic_enum')
makedepends=('python' 'gettext' 'sed' 'python-sphinx-intl'
             'meson' 'ninja' 'help2man' 'python-sphinx'
             'ladspa' 'lv2' 'cmake' 'sassc' 'glib2-devel')
optdepends=('portaudio: portaudio backend'
            'qt5-base: for embedding qt5 plugin UIs'
            'jack: for jack backend'
            'graphviz: process graph export'
            'sdl2: audio backend')
conflicts=("${pkgname%-git}")
provides=("${pkgname%-git}")
options=('!strip')
source=("git+https://gitlab.zrythm.org/zrythm/zrythm/#branch=v1")
md5sums=('SKIP')

pkgver() {
    cd "$srcdir/${pkgname%-git}"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "$srcdir/${pkgname%-git}"
    meson setup build --prefix=/usr -Dmanpage=true -Dcarla=enabled
    ninja -C build
}

check() {
    cd "$srcdir/${pkgname%-git}"
    #ninja -C build test
}

package() {
    cd "$srcdir/${pkgname%-git}"
    install -vDm 644 AUTHORS CONTRIBUTING.md CHANGELOG.md README.md THANKS TRANSLATORS \
        -t "${pkgdir}/usr/share/doc/${pkgname}/"
    install -Dm644 "LICENSES/LicenseRef-ZrythmLicense.txt" "${pkgdir}/usr/share/licenses/ZrythmLicense.txt"
    DESTDIR="${pkgdir}/" ninja -C build install
}