Arch Linux User Repository

This package can now be installed with

$pip3 install gpt-chatbot-cli

Somehow upstream changed the git tag versioning -- now

• git describe --tags returns push-4-g9b38674,
• git describe returns v0.2.1-8-g9b38674.

So I suggest to move from git describe --tags to git describe in pkgver() and closely monitor if upstream changes the version determination mechanism again.

Otherwise, $epoch needs an increment, because push < 0.1.3.

Regards!

@dreieck, I had to uncomment python-setuptools. Without it the build fails.

@slithery0, if you take over dreieck's PKGBUILD, please make this change.

Your PKGBUILD hat a lot of issues I do not want to list one by one.

So I have completely rewritten it.

↗ Here is the working PKGBUILD:

# Maintainer: dreieck (https://aur.archlinux.org/account/dreieck)
# Contributor: slithery0 (https://aur.archlinux.org/account/slithery0)

_pkgname=chatgpt-cli
pkgname="${_pkgname}-git"
pkgver=0.1.3+8.r41.20230204.1746661
pkgrel=1
pkgdesc="A very minimal cli prompt for ChatGPT."
arch=(
  'any'
)
url="https://github.com/slithery0/gpt-chatbot-cli"
license=('MIT')
depends=(
  'python'
  'python-openai'
  'python-termcolor'
  'python-prompt_toolkit'
)
makedepends=(
  'git'
  'python-build'
  'python-installer'
  # 'python-setuptools'
  'python-wheel'
)
provides=(
  "${_pkgname}=${pkgver}"
  "gpt-chatbot-cli=${pkgver}"
  "gpt-chatbot-cli-git=${pkgver}"
)
conflicts=(
  "${_pkgname}"
  "gpt-chatbot-cli"
)
replaces=()
source=(
  "${_pkgname}::git+${url}.git"
)
sha256sums=(
  'SKIP'
)

pkgver() {
  cd "${srcdir}/${_pkgname}"

  _ver="$(git describe --tags | sed -E -e 's|^[vV]||' -e 's|\-g[0-9a-f]*$||' | tr '-' '+')"
  _rev="$(git rev-list --count HEAD)"
  _date="$(git log -1 --date=format:"%Y%m%d" --format="%ad")"
  _hash="$(git rev-parse --short HEAD)"

  if [ -z "${_ver}" ]; then
    error "Could not determine version."
    return 1
  else
    printf '%s' "${_ver}.r${_rev}.${_date}.${_hash}"
  fi
}

prepare() {
  cd "${srcdir}/${_pkgname}"

  git log > "${srcdir}/git.log"
}

build() {
  cd "${srcdir}/${_pkgname}"

  python -m build --wheel --no-isolation
}

package() {
  cd "${srcdir}/${_pkgname}"

  export PYTHONHASHSEED=0
  python -m installer --destdir="${pkgdir}" dist/*.whl

  ln -svr "${pkgdir}/usr/bin/gpt-chatbot-cli"       "${pkgdir}/usr/bin/chatgpt-cli"

  install -D -v -m644 LICENCE                       "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  for _docfile in README.md; do
    install -D -v -m644 "${_docfile}"               "${pkgdir}/usr/share/doc/${_pkgname}/${_docfile}"
  done
  install -d -v -m755                               "${pkgdir}/usr/share/doc/${_pkgname}/wiki"
  install -D -v -m644 "${srcdir}/git.log"           "${pkgdir}/usr/share/doc/${_pkgname}/git.log"
  ln -svf "/usr/share/licenses/${pkgname}/LICENSE"  "${pkgdir}/usr/share/doc/${_pkgname}/LICENSE"
}

Please fix your PKGBUILD, either by jsut using mine or by fixing yours by yourself.

Regards!, and thanks for maintaining.

Install fails with

==> Starting build()...
Defaulting to user installation because normal site-packages is not writeable
ERROR: Could not open requirements file: [Errno 2] No such file or directory: 'requirements.txt'

It seems that this PKGBUILD wants to write outside of ${srcdir}, which is not allowed in build(). (And in package() it may write into ${pkgdir}, but also not directly to the "main" file system.)

Please fix.

Thanks for maintaining!

This package can now be installed with

$pip3 install gpt-chatbot-cli

@NY152 Python should be fetching the env variable "OPENAI_API_KEY".

Make sure you didn't did any typo, and verify if it exist by doing "prntenv" or "env".

Also maybe try adding the variable in "/etc/environment" and restart.

Hello,

I put my API key in environment variable but chatgpt-cli keeps asking me for it.

Is there an ideal practice to follow? What is it ?

Thanks