Solved by ammending the PKGBUILD
This builds perfectly now.
# Maintainer: éclairevoyant
# Contributor: Atif Chowdhury <iftakhar dot awal at gmail dot com>
_pkgname=eww
pkgname="$_pkgname-wayland-git"
pkgver=0.4.0.r23.gc72b881
pkgrel=1
pkgdesc="ElKowar's wacky widgets (Wayland build)"
arch=('x86_64')
url="https://github.com/elkowar/eww"
license=('MIT')
depends=(gtk3 gtk-layer-shell)
makedepends=(git rustup)
provides=("$_pkgname=${pkgver/.r*/}")
conflicts=("eww")
install=$pkgname.install
source=("git+$url.git")
b2sums=('SKIP')
pkgver() {
cd $_pkgname
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd $_pkgname
rustup toolchain install nightly
cargo +nightly build --release --no-default-features --features=wayland
}
package() {
cd $_pkgname
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$_pkgname/"
install -Dm755 target/release/$_pkgname -t "$pkgdir/usr/bin/"
install -d "$pkgdir/etc/xdg/$_pkgname/"
cp -r examples/eww-bar "$pkgdir/etc/xdg/$_pkgname/"
}
Pinned Comments
eclairevoyant commented on 2023-04-03 17:29 (UTC)
Adopted and updated. Make sure to fetch the signing keys from GitHub and import them before building: