Package Details: gmsh 4.13.1-1

Git Clone URL: https://aur.archlinux.org/gmsh.git (read-only, click to copy)
Package Base: gmsh
Description: An automatic 3D finite element mesh generator with pre and post-processing facilities
Upstream URL: https://gmsh.info
Licenses: GPL-2.0-or-later
Submitter: S1G1
Maintainer: gborzi (carlosal1015, gpettinello)
Last Packager: carlosal1015
Votes: 62
Popularity: 0.007952
First Submitted: 2006-04-04 23:31 (UTC)
Last Updated: 2024-05-25 16:15 (UTC)

Sources (3)

Latest Comments

« First ‹ Previous 1 2 3 4 5 6 7 .. 21 Next › Last »

billypilgrim commented on 2022-11-08 16:07 (UTC)

Thanks for packaging this!

I've just been faffing around getting the included Python wrapper to work and I've got a suggestion: if you symlink /usr/share/gmsh/api/python/gmsh.py to /usr/lib/python3.10/site-packages/gmsh.py then it'll work out of the box as a Python package. Otherwise you'll probably have to mess around with your PYTHON_PATH or something.

Perhaps you could do this in the package?

entshuld commented on 2022-11-02 16:46 (UTC)

warning: mesa 22.2.1 breaks gmsh <= 4.10.5. https://gitlab.onelab.info/gmsh/gmsh/-/issues/2161

carlosal1015 commented on 2022-09-19 14:27 (UTC)

Thank you so much, I appreciate it.

gborzi commented on 2022-09-19 12:42 (UTC)

@gpettinello and @carlosal1015 I've added both of you as co-maintainers.

carlosal1015 commented on 2022-09-12 17:49 (UTC)

I am offer as volunteer to (co)maintain the package as doing with gmsh-bin.

gborzi commented on 2022-09-12 17:18 (UTC)

@gpettinello If you are interested in maintaining the package I can orphan it. I don't have much time anymore.

gborzi commented on 2022-09-12 17:16 (UTC)

Sorry for not answering the messages, I've been away for a while.

entshuld commented on 2022-08-25 16:41 (UTC) (edited on 2022-08-25 16:41 (UTC) by entshuld)

In package():

echo 'export PYTHONPATH="/usr/share/gmsh/api/python/:$PYTHONPATH"' > "$pkgdir/etc/profile.d/gmsh.sh"
echo 'setenv PYTHONPATH="/usr/share/gmsh/api/python/:$PYTHONPATH"' > "$pkgdir/etc/profile.d/gmsh.csh"

gpettinello commented on 2022-08-13 13:39 (UTC)

@gborzi I'm ready to submit the updated PKGBUILD but I'm not allowed to do it. Please could you add me in the list of contributors or could you update yourself:

# Maintainer: gborzi <gborzi@ieee.org>
# Contributor: mickele <mimocciola@yahoo.com>
# Contributor: gpettinello <g_pet@hotmail.com>
pkgname=('gmsh' 'gmsh-docs')
pkgver=4.10.5
pkgrel=1
pkgdesc="An automatic 3D finite element mesh generator with pre and post-processing facilities."
arch=('x86_64')
url="http://gmsh.info/"
license=('custom')
makedepends=('cmake' 'desktop-file-utils' 'sed' 'swig' 'texlive-core' 'voro++'
             'fltk' 'med' 'opencascade' 'cairo' 'metis' 'alglib' 'ann'
             'glu' 'cgns' 'lapack')
options=(!emptydirs)
source=("${url}src/${pkgname}-${pkgver}-source.tgz" gmsh.desktop gmsh.completion)
sha256sums=('cc030c5aee65e7d58f850b8b6f55a68945c89bc871f94e1239279f5a210fc4ea'
            '43a8ca33ac917ee7196fdae305ff2c8cb9ae1072569ee546c0ce8ff580c966ae'
            '11605e97636a56cf51e445e65019526ee253bd2e0553fb71ba6d94488dcd34ef')

prepare() {
   cd "${srcdir}/${pkgname}-${pkgver}-source"

   # Help links to local doc (package gmsh-docs)
   sed -e "s|https://gmsh.info/doc/texinfo/|file:///usr/share/doc/gmsh/|" \
       -i src/fltk/graphicWindow.cpp
   sed -e "s|https://gmsh.info/dev/doc/texinfo/|file:///usr/share/doc/gmsh/|" \
       -i src/fltk/graphicWindow.cpp
   sed -e "s|https://gmsh.info/|file:///usr/share/licenses/gmsh/|" \
       -i src/fltk/helpWindow.cpp

}

build() {
   cd "${srcdir}/${pkgname}-${pkgver}-source"

   mkdir -p build

   cd build

   cmake -DCMAKE_INSTALL_PREFIX:PATH=/usr -DENABLE_BUILD_SHARED=ON \
      -DENABLE_SYSTEM_CONTRIB=ON -DENABLE_BLAS_LAPACK=ON \
      -DENABLE_CGNS=ON -DENABLE_ANN=ON -DENABLE_ALGLIB=ON \
      -DENABLE_METIS=ON -DENABLE_OCC=ON -DENABLE_MED=ON \
      -DENABLE_VOROPP=ON -DENABLE_EIGEN=OFF -DENABLE_PETSC=FALSE ..

   make
   LC_ALL=C make doc
}

package_gmsh() {
   depends=('fltk' 'med' 'opencascade' 'cairo' 'metis' 'alglib' 'ann'
            'glu' 'cgns' 'lapack')
   optdepends=('gmsh-docs: docs for gmsh'
            'python2: for gmsh.py'
            'python: for gmsh.py'
            'julia: for gmsh.jl')

   cd "${srcdir}/${pkgname}-${pkgver}-source/build"
   make DESTDIR=${pkgdir} install
   install -D -m644 "${pkgdir}/usr/lib/gmsh.py" "${pkgdir}/usr/share/gmsh/api/python/gmsh.py"
   install -D -m644 "${pkgdir}/usr/lib/gmsh.jl" "${pkgdir}/usr/share/gmsh/api/julia/gmsh.jl"
   rm -f "${pkgdir}/usr/lib/gmsh.py" "${pkgdir}/usr/lib/gmsh.jl"
   install -d "$pkgdir/etc/profile.d"
   echo 'export JULIA_LOAD_PATH="/usr/share/gmsh/api/julia/:$JULIA_LOAD_PATH"' > "$pkgdir/etc/profile.d/gmsh.sh"
   echo 'setenv JULIA_LOAD_PATH "/usr/share/gmsh/api/julia/:$JULIA_LOAD_PATH"' > "$pkgdir/etc/profile.d/gmsh.csh"


   install -d "${pkgdir}/usr/share/pixmaps/${pkgname}"
   install -m644 ../utils/icons/*.png "${pkgdir}/usr/share/pixmaps/${pkgname}"
   install -D -m644 ../utils/icons/gmsh-no-text.png "${pkgdir}/usr/share/icons/${pkgname}.png"

   desktop-file-install --dir="${pkgdir}/usr/share/applications" \
        "${srcdir}/${pkgname}.desktop"

   install -D -m 644 "../LICENSE.txt" "${pkgdir}/usr/share/licenses/$pkgname/LICENSE.txt"
   install -D -m 644 "../CREDITS.txt" "${pkgdir}/usr/share/licenses/$pkgname/CREDITS.txt"
   install -D -m644 $srcdir/gmsh.completion $pkgdir/etc/bash_completion.d/gmsh

   rm -rf ${pkgdir}/usr/share/doc
}

package_gmsh-docs() {
   pkgdesc="TXT, HMTL and PDF doc for Gmsh"
   arch=('any')
   license=('GPL2')

   cd "${srcdir}/${pkgbase}-${pkgver}-source/build"

   bsdtar -xf ${pkgbase}-${pkgver}-*.tgz

   cd "doc/texinfo"

   install -D -m644 gmsh.html "${pkgdir}/usr/share/doc/gmsh/gmsh.html"
   install -D -m644 gmsh.txt "${pkgdir}/usr/share/doc/gmsh/gmsh.txt"
   install -D -m644 gmsh.pdf "${pkgdir}/usr/share/doc/gmsh/gmsh.pdf"
   install -D -m644 gmsh.info "${pkgdir}/usr/share/info/gmsh.info"
}

carlosal1015 commented on 2022-08-09 17:58 (UTC)

Hi, I would like to ask if is possible to add as dependency explicitly the new package (3 days ago) med-openmpi since by default is installing med otherwise pacman always ask

:: Replace med with community/med-openmpi? [Y/n] 
resolving dependencies...
looking for conflicting packages...
:: hdf5-openmpi and hdf5 are in conflict. Remove hdf5? [y/N]

« First ‹ Previous 1 2 3 4 5 6 7 .. 21 Next › Last »