Arch Linux User Repository

Because upstream has changed their versioning scheme, pkgver() now returns gping.v1.2.3.r2.g5960439, which is interpreted as a downgrade from 0.1.6.r9.g3179477, which is what the PKGBUILD reports as the version. This causes issues with AUR helpers which can check for updates as they think that the version that is built is always older than the version available from the AUR. It would be nice if the pkgver was updated to the current value, or, better yet, was updated to a generic value like latest, or maybe even set to 0, as suggested in the forums.

A few issues about PKGBUILD:

• You have to trim v from the version. Update sed as following:

pkgver() {
    cd "$pkgname"
    git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

• Specify iputils package in depends. (provides ping which is necessary for gping to work)
• --locked flag must be specified in cargo build for package reproducibility.
• LICENSE is present in the upstream. Please install it.

Updated PKGBUILD:

# Maintainer: Mateen Ulhaq <mulhaq2005+aur at gmail dot com>

pkgname=gping-git
pkgver=0.1.6.r9.g3179477
pkgrel=1
pkgdesc="Ping, but with a graph"
arch=("x86_64")
url="https://github.com/orf/gping"
license=("MIT")
depends=("iputils")
makedepends=("cargo" "git")
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("$pkgname::git+$url")
sha256sums=("SKIP")

pkgver() {
    cd "$pkgname"
    git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "$pkgname"
    cargo build --release --locked
}

package() {
    cd "$pkgname"
    install -Dm755 "target/release/${pkgname%-git}" -t "$pkgdir/usr/bin"
    install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/gping"
    install -Dm644 "readme.md" -t "$pkgdir/usr/share/doc/gping"
}

FYI, a LICENSE file is available now: https://github.com/orf/gping/commit/4f03d45a012fccd62f384a16c3ef0d3b3e954132