Package Details: libvpx1.10 1.10.0-1

Git Clone URL: https://aur.archlinux.org/libvpx1.10.git (read-only, click to copy)
Package Base: libvpx1.10
Description: VP8 and VP9 codec, provides libvpx.so.6
Upstream URL: https://www.webmproject.org/
Licenses: BSD
Provides: libvpx.so
Submitter: detian
Maintainer: detian
Last Packager: detian
Votes: 1
Popularity: 0.199750
First Submitted: 2025-02-12 16:24 (UTC)
Last Updated: 2025-02-25 08:00 (UTC)

Dependencies (3)

Required by (14)

Sources (1)

Latest Comments

detian commented on 2025-02-25 08:00 (UTC)

@young.acinonyx thanks, updated!

young.acinonyx commented on 2025-02-22 00:19 (UTC) (edited on 2025-02-25 02:10 (UTC) by young.acinonyx)

Hi, detian!

I noticed that the current libvpx1.10 PKGBUILD uses a source from chromium.googlesource.com that produces a non-deterministic SHA256 sum. This is likely caused by dynamic metadata in the archive. As an alternative, switching to a GitHub release tarball (which is reproducible) would allow a fixed checksum.

For example, using the GitHub URL for v1.10.0 and adjusting the package() function to use DESTDIR instead of DIST_DIR fixes the install target error. Please see the temporary corrected PKGBUILD below.

Best regards, young.acinonyx

# Maintainer: detiam <dehe_tian@outlook.com>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>

pkgname=libvpx1.10
pkgver=1.10.0
pkgrel=1
pkgdesc='VP8 and VP9 codec, provides libvpx.so.6'
arch=(x86_64)
url="https://www.webmproject.org/"
license=(BSD)
depends=(gcc-libs)
makedepends=(git nasm)
provides=(libvpx.so)
source=("https://github.com/webmproject/libvpx/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('d8dca8af9a4b9e9f06b8a710ccdf68c67d4c32b701cc428cdb8c95b5fa20e66a')

build() {
  cd "$srcdir/libvpx-${pkgver}"
  ./configure \
    --prefix=/usr \
    --disable-install-docs \
    --disable-install-srcs \
    --enable-pic \
    --enable-postproc \
    --enable-runtime-cpu-detect \
    --enable-shared \
    --enable-vp8 \
    --enable-vp9 \
    --enable-vp9-highbitdepth \
    --enable-vp9-temporal-denoising \
    --disable-unit-tests
  make
}

package() {
  cd "$srcdir/libvpx-${pkgver}"
  make install DESTDIR="$pkgdir"
  # Remove unneeded files so that only the shared library remains
  rm -rf "$pkgdir/usr"/{bin,include,lib/{libvpx.{a,so},pkgconfig},share}
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}

# vim: ts=2 sw=2 et:

detian commented on 2025-02-12 16:30 (UTC) (edited on 2025-02-12 18:42 (UTC) by detian)

For GE-Proton9-13

(wine:67142): GStreamer-WARNING **: 23:40:29.654: Failed to load plugin '/usr/share/steam/compatibilitytools.d/proton-ge-custom/files/lib64/gstreamer-1.0/libgstvpx.so': libvpx.so.6: cannot open shared object file: No such file or directory