Arch Linux User Repository

Looks pushing is open: https://lists.archlinux.org/archives/list/aur-general@lists.archlinux.org/thread/P5C7GZ4C3OJIH4EXJ62JAF6X6PY2BCQ4/

I'll update when the AUR ban on pushes is lifted - unfortunately I can't update anything until they lift the restrictions.

EDIT: updated

Hi. Updated PKGBUILD for new version: 7.6.4

pkgname=powershell-bin
_pkgname=${pkgname%-bin}
pkgver=7.6.4
pkgrel=1
pkgdesc="A cross-platform automation and configuration tool/framework (binary package)"
arch=(x86_64 armv7h aarch64)
url="https://github.com/Powershell/Powershell"
license=(MIT)
depends=(
  gcc-libs
  glibc
)
optdepends=('lttng-ust2.12: CoreCLR tracing')
provides=(powershell)
conflicts=(powershell)
install=powershell.install
_archive="$pkgname-$pkgver-$pkgrel"
_artifact="$_archive.tar.gz"
source_armv7h=("$_artifact::$url/releases/download/v$pkgver/powershell-$pkgver-linux-arm32.tar.gz")
source_aarch64=("$_artifact::$url/releases/download/v$pkgver/powershell-$pkgver-linux-arm64.tar.gz")
source_x86_64=("$_artifact::$url/releases/download/v$pkgver/powershell-$pkgver-linux-x64.tar.gz")
noextract=("$_artifact")
sha256sums_armv7h=('34b19245f0264eeeea94d382ffc033891095d9a2b6d0392ed66b909bf0d3dff1')
sha256sums_aarch64=('d4ef2382fa452f2ccbdb48a01adbbce9ed64954872123970c16be6d086d1224b')
sha256sums_x86_64=('4471b5a36bfe86ec7af8525d36bb1cacba0128e7aac22d05cc064bc00e604721')

prepare() {
  mkdir -p "$_archive"
  tar -xf $_artifact -C "$_archive"
}

package() {
  cd "$_archive"

  local pkgnum=${pkgver:0:1}

  install -dm755 "$pkgdir/usr/lib/$_pkgname-$pkgnum"
  cp -a -t "$pkgdir/usr/lib/$_pkgname-$pkgnum" ./*
  # The pwsh executable is not executable in the archive, for some reason.
  chmod 755 "$pkgdir/usr/lib/$_pkgname-$pkgnum/pwsh"

  install -dm755 "$pkgdir/usr/bin"
  ln -s "/usr/lib/$_pkgname-$pkgnum/pwsh" "$pkgdir/usr/bin/pwsh"

  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.txt
}

Thanks that fixed it, not sure what happened but I'll make sure to remember that in the future

@LiamillionSS that's strange - the hash is 856D0765D2332377F9D7A4AEA76EFDFDE4DE51446E7738DDE2DFDA41DBA9E2A7 on both the PKGBUILD and the release page at https://github.com/PowerShell/PowerShell/releases/tag/v7.6.3

can you try re-syncing and doing a clean build?

Hi, the tar.gz hash seems to be out of date

==> Validating source_x86_64 files with sha256sums...
    powershell-bin-7.6.3-1.tar.gz ... FAILED
==> ERROR: One or more files did not pass the validity check!

thank you, PKGBUILD is updated and i can confirm it's current now. appreciate it!

@dylanhall, added you as a co-maintainer, thanks

is this orphaned? I use it daily and it has a warning when it's out of date, I'm currently maintaining a copy locally just so i can update. I'd be happy to start updating it here.

version 7.6.0 is out. Here is an updated PKGBUILD.

pkgname=powershell-bin
_pkgname=${pkgname%-bin}
pkgver=7.6.0
pkgrel=1
pkgdesc="A cross-platform automation and configuration tool/framework (binary package)"
arch=(x86_64 armv7h aarch64)
url="https://github.com/Powershell/Powershell"
license=(MIT)
depends=(
  gcc-libs
  glibc
)
optdepends=('lttng-ust2.12: CoreCLR tracing')
provides=(powershell)
conflicts=(powershell)
install=powershell.install
_archive="$pkgname-$pkgver-$pkgrel"
_artifact="$_archive.tar.gz"
source_armv7h=("$_artifact::$url/releases/download/v$pkgver/powershell-$pkgver-linux-arm32.tar.gz")
source_aarch64=("$_artifact::$url/releases/download/v$pkgver/powershell-$pkgver-linux-arm64.tar.gz")
source_x86_64=("$_artifact::$url/releases/download/v$pkgver/powershell-$pkgver-linux-x64.tar.gz")
noextract=("$_artifact")
sha256sums_x86_64=('04517472CF57D7F9CBD93897DA9BED467C73CA6063C29D7655EBC20AA1D6023F')
sha256sums_armv7h=('ECDFF7807C239ADF6A600632E8E686367A10F23FB2435C668FBE19B06DCC136E')
sha256sums_aarch64=('DDDF7564FB3B52DC26BE5580FC5B4E08EB3FA65B094488AAE6D4B3CAD5FEA460')

prepare() {
  mkdir -p "$_archive"
  tar -xf $_artifact -C "$_archive"
}

package() {
  cd "$_archive"

  local pkgnum=${pkgver:0:1}

  install -dm755 "$pkgdir/usr/lib/$_pkgname-$pkgnum"
  cp -a -t "$pkgdir/usr/lib/$_pkgname-$pkgnum" ./*
  # The pwsh executable is not executable in the archive, for some reason.
  chmod 755 "$pkgdir/usr/lib/$_pkgname-$pkgnum/pwsh"

  install -dm755 "$pkgdir/usr/bin"
  ln -s "/usr/lib/$_pkgname-$pkgnum/pwsh" "$pkgdir/usr/bin/pwsh"

  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.txt
}