Arch Linux User Repository

Since the package is out of date and doesn't build, the PKGBUILD file needs to be updated. As of today 19-05-25, the following PKGBUILD serves to build the current version. Don't forget to calculate the md5sums instead of skipping them as I do in the provided example if the PKGBUILD is updated.

# Maintainer: normaldotcom
pkgname=python-pyenet-git
pkgver=r174.175f0c5
pkgrel=1
pkgdesc="Python wrapper for the ENet networking library"
arch=('any')
url="https://github.com/aresch/pyenet"
license=('BSD' 'MIT')
depends=('python')
makedepends=('git' 'cython' 'python-setuptools')
source=("git+https://github.com/aresch/pyenet.git"
        "http://enet.bespin.org/download/enet-1.3.18.tar.gz")
md5sums=('SKIP'
         'SKIP')

pkgver() {
    cd "$srcdir/pyenet"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd "$srcdir/pyenet"
    # Copy the ENet source to the expected directory
    rm -rf enet
    cp -r "$srcdir/enet-1.3.18" "$srcdir/pyenet/enet"
}

build() {
    cd "$srcdir/pyenet"
    python setup.py build
}

package() {
    cd "$srcdir/pyenet"
    python setup.py install --root="$pkgdir" --optimize=1 --skip-build
}