Arch Linux User Repository

Here is the PKGBUILD that works for me, copied from extra/rclone

_pkgname=rclone
pkgname="${_pkgname}-git"
pkgver=v1.38.r223.g7c972d37
pkgrel=1
pkgdesc="Sync files to and from Google Drive, S3, Swift, Cloudfiles, Dropbox and Google Cloud Storage"
arch=('x86_64')
url="http://rclone.org/"
license=('MIT')
depends=('glibc')
makedepends=('python2' 'pandoc' 'go-pie')
source=("${_pkgname}::git+https://github.com/ncw/${_pkgname}.git")
conflicts=("${_pkgname}")
provides=("${_pkgname}")
sha256sums=('SKIP')

pkgver() {
    cd "${_pkgname}"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd ${_pkgname}

  sed -i "1s/python$/&2/" bin/make_manual.py

  mkdir -p .gopath/src/github.com/ncw
  ln -sf "$PWD" .gopath/src/github.com/ncw/rclone
  export GOPATH="$PWD/.gopath"

  go get github.com/ncw/rclone
}

build() {
  cd ${_pkgname}/.gopath/src/github.com/ncw/rclone

  PATH="$GOPATH/bin:$PATH" make TAG=v$pkgver rclone doc
}

check() {
  cd ${_pkgname}/.gopath/src/github.com/ncw/rclone
  make TAG=v$pkgver test || warning "Tests failed"
}

package() {
  cd ${_pkgname}/.gopath/src/github.com/ncw/rclone
  make TAG=v$pkgver DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"

  install -Dm644 rclone.1 "$pkgdir/usr/share/man/man1/rclone.1"
  install -d "$pkgdir/usr/share/doc/$pkgname"
  install -t "$pkgdir/usr/share/doc/$pkgname" -m644 MANUAL.html MANUAL.txt
}

Any interest in maintaining this package?

@serialoverflow: You can use a pkgver() function, see the wiki <https://wiki.archlinux.org/index.php/VCS_package_guidelines#Git>

And yes, this fails to build.

Error when trying to build:

go install -v --ldflags "-s -X github.com/ncw/rclone/fs.Version=v1.36-222-gf3c7e1a9"
go install: no install location for directory /tmp/pkgbuild-0/rclone-git/src/rclone outside GOPATH
For more details see: 'go help gopath'
make: *** [Makefile:18: rclone] Error 1
==> ERROR: A failure occurred in build().
Aborting...

==> ERROR: the build failed
-> Status
failed (1): rclone-git

it does pull the latest version from git (master branch). that means it is usually even more current than the "latest" package under http://beta.rclone.org.
as far as i know, there is no better way to display the version of git packages. if you know a better one, please share but this seems to be the convention.

can this package just pull the latest git version from github, rather be version controlled? (Its currently out of date too)