Package Details: rust-doom-git r436.2efa6ae-1

Git Clone URL: https://aur.archlinux.org/rust-doom-git.git (read-only, click to copy)
Package Base: rust-doom-git
Description: A little Doom 1 & 2 Renderer written in Rust.
Upstream URL: https://github.com/cristicbz/rust-doom
Keywords: doom doom2 rust
Licenses: Apache
Conflicts: rust-doom
Provides: rust-doom
Submitter: 0x647262
Maintainer: deid84
Last Packager: FredBezies
Votes: 3
Popularity: 0.000001
First Submitted: 2017-02-09 20:10 (UTC)
Last Updated: 2021-08-03 15:04 (UTC)

Latest Comments

Neko-san commented on 2022-01-28 07:21 (UTC) (edited on 2022-01-28 07:22 (UTC) by Neko-san)

Until this package gets picked up again, I'm going to leave information here to help anyone needing info to make it compile; edit the PKGBUILD and .SRCINFO as follows to make certain no issue should occur (so long as upstream has no errors):

PKGBUILD:

# Maintainer: Frederic Bezies <fredbezies at gmail dot com>
# Contributor: Dan Beste <dan.ray.beste@gmail.com>

# TODO
#   1. Firejail profile + script

pkgname='rust-doom-git'
_gitname='rust-doom'
_execname='rs_doom'
pkgver=r436.2efa6ae
pkgrel=1
pkgdesc='A little Doom 1 & 2 Renderer written in Rust.'
arch=('i686' 'x86_64')
url='https://github.com/cristicbz/rust-doom'
license=('Apache')
depends_x86_64=('sdl2' 'sdl2_ttf')
depends_i686=('lib32-sdl2' 'lib32-sdl2_ttf')
makedepends=('cargo' 'git' 'rust')
provides=("${_gitname}")
conflicts=("${_gitname}")
source=('git+https://github.com/cristicbz/rust-doom.git')
sha256sums=('SKIP')
options=(!lto)

pkgver() {
  cd "${_gitname}"

  printf "r%s.%s"                  \
    "$(git rev-list --count HEAD)" \
    "$(git rev-parse --short HEAD)"
}

build() {
  if [ "$CC" != "gcc" ] || [ "$CXX" != "g++" ]; then
    export CC=gcc
    export CXX=g++
    export LD="ld"
    export AR="ar"
    export NM="nm"
    export AS="as"
    export RANLIB="ranlib"
    export STRIP="strip"
    export OBJCOPY="objcopy"
    # Reset debug flags to makepkg.conf defaults, in case Clang is globally set
    export DEBUG_CFLAGS="-g -fvar-tracking-assignments"
    export DEBUG_CXXFLAGS="-g -fvar-tracking-assignments"
  fi
  cd "${_gitname}"

  cargo build --release
}

check() {
  cd "${_gitname}"

  cargo test
}

package() {
  cd "${_gitname}"

  install -D -m 755               \
    "target/release/${_execname}" \
    "${pkgdir}/usr/bin/${_gitname}"
  install -D -m 644 \
    LICENSE         \
    "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim: ts=2 sw=2 et:

.SRCINFO:

pkgbase = rust-doom-git
    pkgdesc = A little Doom 1 & 2 Renderer written in Rust.
    pkgver = r436.2efa6ae
    pkgrel = 1
    url = https://github.com/cristicbz/rust-doom
    arch = i686
    arch = x86_64
    license = Apache
    makedepends = cargo
    makedepends = git
    makedepends = rust
    provides = rust-doom
    conflicts = rust-doom
    source = git+https://github.com/cristicbz/rust-doom.git
    sha256sums = SKIP
    depends_i686 = lib32-sdl2
    depends_i686 = lib32-sdl2_ttf
    depends_x86_64 = sdl2
    depends_x86_64 = sdl2_ttf
    options = !lto

pkgname = rust-doom-git