Arch Linux User Repository

For those who want to enable users in the plugdev-group to access the unifying receiver (e.g. when you are not using elogind/ systemd):

enable-plugdev-group-access.patch:

Only in solaar-git: build
Only in solaar-git/lib/solaar: __pycache__
diff -r -U1 solaar-git.orig/rules.d/42-logitech-unify-permissions.rules solaar-git/rules.d/42-logitech-unify-permissions.rules
--- solaar-git.orig/rules.d/42-logitech-unify-permissions.rules 2018-11-30 11:25:28.556373309 +0100
+++ solaar-git/rules.d/42-logitech-unify-permissions.rules  2018-11-30 11:32:13.066966601 +0100
@@ -49,3 +49,3 @@
 # Grant members of the "plugdev" group access to receiver (useful for SSH users)
-#MODE="0660", GROUP="plugdev"
+MODE="0660", GROUP="plugdev"

PKGBUILD which applies this patch:

# Contributor: David Runge <dave@sleepmap.de>
# Contributor: Arnaud Taffanel <dev@taffanel.org>
# Contributor: Victor Häggqvist <aur a snilius d com>

_name=Solaar
pkgname=solaar-git
pkgver=0.9.2.r247.gb852903
pkgrel=1
pkgdesc="Device manager for Logitech's Unifying receiver peripherals"
url="https://pwr.github.com/Solaar/"
license=('GPL2')
arch=('any')
provides=("solaar")
conflicts=("solaar")
depends=('gtk3' 'libnotify' 'python-dbus' 'python-gobject' 'python-pyudev')
source=("${pkgname}::git+https://github.com/pwr/Solaar.git")
sha512sums=('SKIP')

source+=("enable-plugdev-group-access.patch::http://ix.io/1uT9")
sha512sums+=('b47b253798577d91376289f9dd4b231e4653e22def0c529a77134554ba0f63b438c3a016fe0e0267e43e4c243a54770dec5e0498153ef875588cdc235507e2f7')

prepare() {
  cd "${srcdir}/${pkgname}"
  for _patch in 'enable-plugdev-group-access.patch'; do
    msg "Applying patch '${_patch}' ..."
    patch --follow-symlinks -N -p1 -i "${srcdir}/${_patch}"
  done
}
pkgver() {
  cd "${pkgname}"
  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "${pkgname}"
  python setup.py build
}

package() {
  cd "${pkgname}"
  python setup.py install --skip-build \
    --optimize=1 \
    --prefix=/usr \
    --root="${pkgdir}/"
  # udev
  install -vDm 644 rules.d/42-logitech-unify-permissions.rules \
    "${pkgdir}/usr/lib/udev/rules.d/42-logitech-unify-permissions.rules"
  # docs
  install -vDm 644 {ChangeLog,README.md} \
    -t "${pkgdir}/usr/share/doc/${pkgname}/"
}
# vim:set ts=2 sw=2 et:

Patch for the AUR PKGBUILD (to be used with e.g. customizepkg-scripting):

--- PKGBUILD.orig   2018-11-30 11:25:06.536341012 +0100
+++ PKGBUILD    2018-11-30 11:37:58.047472581 +0100
@@ -18,2 +18,12 @@

+source+=("enable-plugdev-group-access.patch::http://ix.io/1uT9")
+sha512sums+=('b47b253798577d91376289f9dd4b231e4653e22def0c529a77134554ba0f63b438c3a016fe0e0267e43e4c243a54770dec5e0498153ef875588cdc235507e2f7')
+
+prepare() {
+  cd "${srcdir}/${pkgname}"
+  for _patch in 'enable-plugdev-group-access.patch'; do
+    msg "Applying patch '${_patch}' ..."
+    patch --follow-symlinks -N -p1 -i "${srcdir}/${_patch}"
+  done
+}
 pkgver() {

@TrialnError Good points! I hadn't paid much attention to this package as upstream had been historically inactive for a long time, and I just needed this package ported from the old AUR when the migration to git happened. Things have changed a lot since then...

I took the community version and added VCS back to it, so it should be all clean and modern now :)

Hey Max-P. Some points that propably could be improved. I suppose a good starting point could be the community maintained solaar package. What I noticed: pygtk still as a dep? This if for python2 bindings and it seems solaar moved to python3 in the meantime. python-dbus is missing as a dep?

.install files don't need to be in the source line. They have their install= var. Community maintained one doesn't have a .install file anymore. And why is in the PKGBUILD, under the package function, a part from the install file?

Additionally regarding the VCS Package guidelines. The upstream repo does have tags. So the prefered pkgver in those cases is the first listed on the wiki page.

And regarding packaging of python packages see: https://wiki.archlinux.org/index.php/Python_package_guidelines#distutils

(build and package two separate steps)

@JasonP: technically yes, as it builds from latest master, whereas the community package still uses the old 0.9.2 tag

Is this package more up to date than https://www.archlinux.org/packages/community/any/solaar/ ?

Just an question, because I need to replug the receiver every-time to get Solaar to work (add user to plugdev group). Do I need to edit something in the udev rule? I'm using KDE + tlp. Thanks.

Ha, of course upstream finally becomes active again and starts merging stuff right after I finally decide to fork.

Switched back to upstream source!

Upstream has recently merged a bunch of PRs (including the Python 3.7 fix). Could you switch back to the upstream source?

I've backported the fix for python 3.7 to 0.9.2:

https://gist.github.com/Ikke/fc9e7db6eb04c5cbb7f7113a21b61281

I've temporarily forked the repo and merged the Python PR as well as the ones introducing new device support. I was hoping upstream would eventually catch up and merge things, but now the package is broken I'm forced to go this way.

Sorry for the poor maintenance of this package btw.

Seems like the upstream package owner went MIA. There appears to be one or two folks with write access to the repo, so just a matter of time waiting for the package to be sorted out.

There's a PR for the recent Python 3.7 issues: https://github.com/pwr/Solaar/pull/448/files

Here's to hoping the upstream package maintenance gets sorted out soon.