Arch Linux User Repository

Thank you for the reminder, @loziniak, I forgot to reset the pkgrel, I hope to do this during the next update.

@atjcraig, I think the @loziniak's message was addressed to me, the maintainer, who released a new update.

Thanks loziniak, I updated my comment

About pkgrel:

"When a new version of the software is released, this value must be reset to 1"

https://wiki.archlinux.org/title/PKGBUILD#pkgrel

PR submitted for latest version (5.8.0.35)

Updated PKGBUILD in case anyone needs it now:

# Maintainer: Yurii Kolesnykov <root@yurikoles.com>
#
# PRs are welcome here: https://github.com/yurikoles-aur/upwork
#

pkgname=upwork
_pkgname='Upwork'
pkgver=5.8.0.35
_hashver='42e992f623e44665'
pkgrel=1
pkgdesc='Track your time for Hourly Payment Protection. Stay connected.'
arch=(x86_64)
url='https://www.upwork.com/ab/downloads/?os=linux'
license=(custom)
depends=(alsa-lib gtk3 libxss nss)
conflicts=(upwork-beta)
_useragent="User-Agent: Mozilla/5.0 (X11; Linux x86_64; rv:108.0) Gecko/20100101 Firefox/108.0"
_rawver=${pkgver//./_}
DLAGENTS=("https::/usr/bin/curl --tlsv1.3 -H ${_useragent// /\\ } %u -o %o")
source=(https://upwork-usw2-desktopapp.upwork.com/binaries/v${_rawver}_${_hashver}/upwork_${pkgver}_amd64.deb
        LICENSE)
sha256sums=('4aebf6dd32fa9791e190e4914f9e8ba45459271b922d855cd6e4fa85ef23eced'
            '793d8d7bc0f088c48798bda3d5483972636c6b8c5dcd9aeaf85411f7d4547b38')

prepare() {
    bsdtar -xpf data.tar.xz
}

package() {
    # Base
    local _optdir="${pkgdir}"/opt/${_pkgname}

    install -dm755 "${_optdir}"
    cp -dr --no-preserve=ownership opt/${_pkgname}/* "${_optdir}"

    # Code ref: https://github.com/electron-userland/electron-builder/blob/master/packages/app-builder-lib/templates/linux/after-install.tpl
    # SUID chrome-sandbox for Electron 5+
    test -e "${_optdir}"/chrome-sandbox && chmod 4755 "${_optdir}"/chrome-sandbox || true

    # Exec
    install -dm755 "${pkgdir}"/usr/bin/
    ln -s /opt/${_pkgname}/${pkgname} "${pkgdir}"/usr/bin/

    # Menu
    install -Dm644 usr/share/applications/${pkgname}.desktop "${pkgdir}"/usr/share/applications/${pkgname}.desktop

    # Icons
    install -dm755 "${pkgdir}"/usr/share
    cp -dr --no-preserve=ownership usr/share/icons "${pkgdir}"/usr/share

    # License
    install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}

Many people had a problem with logging into the app, where the browser is used in process. Somehow the scheme handler wasn'picked up by the browser (Firefox in my case), and the solution was to use xdg-open:

https://community.upwork.com/t5/Support-Forum/Not-possible-to-use-upwork-desktop-app-after-an-update/m-p/1469529/highlight/true#M109896

@PositivePulse, you shouldn't have to edit your GDM config just to switch to Xorg. Just click the gear icon and select the Gnome on Xorg session.

Shame how they completely disable the functionality on Xorg now though. Before it was working fine on KDE with a few workarounds.

@PositivePulse Feel free to let upwork know about this issue on their support forum.

temporary workaround is to switch to xorg (this is huge ....) on my system it was a matter of editing /etc/gdm/custom.conf and uncommeting WaylandEnable=false. After sudo systemctl restart gdm, screenshots work. But I can not stress enough how disappointed I am

ok so this broke badly for me. I'm using wayland. Screenshots no longer work, it literally suggests: "use Xorg". This annoying built-in upgrade feature is preventing me to use the app unless I build it myself with the PKGBUILD from below. I've had problems with this app before, it was pretty bad, like 9/10 bad, but now its 90/10. any help would be appreciated. it seems like this package is now pointless unless you use Xorg.

PKGBUILD for today's update (v5.8.0.33)

# Maintainer: Yurii Kolesnykov <root@yurikoles.com>
#
# PRs are welcome here: https://github.com/yurikoles-aur/upwork
#

pkgname=upwork
_pkgname='Upwork'
pkgver=5.8.0.33
_hashver='42e992f623e44665'
pkgrel=2
pkgdesc='Track your time for Hourly Payment Protection. Stay connected.'
arch=(x86_64)
url='https://www.upwork.com/ab/downloads/?os=linux'
license=(custom)
depends=(alsa-lib gtk3 libxss nss)
conflicts=(upwork-beta)
_useragent="User-Agent: Mozilla/5.0 (X11; Linux x86_64; rv:108.0) Gecko/20100101 Firefox/108.0"
_rawver=${pkgver//./_}
DLAGENTS=("https::/usr/bin/curl --tlsv1.3 -H ${_useragent// /\\ } %u -o %o")
source=(https://upwork-usw2-desktopapp.upwork.com/binaries/v${_rawver}_${_hashver}/upwork_${pkgver}_amd64.deb
        LICENSE)
sha256sums=('314d2eb1301f34d30df0e6264ba75653a5e4da8e5d83927457b3908afddd2ee8'
            '793d8d7bc0f088c48798bda3d5483972636c6b8c5dcd9aeaf85411f7d4547b38')

prepare() {
    bsdtar -xpf data.tar.xz
}

package() {
    # Base
    local _optdir="${pkgdir}"/opt/${_pkgname}

    install -dm755 "${_optdir}"
    cp -dr --no-preserve=ownership opt/${_pkgname}/* "${_optdir}"

    # Code ref: https://github.com/electron-userland/electron-builder/blob/master/packages/app-builder-lib/templates/linux/after-install.tpl
    # SUID chrome-sandbox for Electron 5+
    test -e "${_optdir}"/chrome-sandbox && chmod 4755 "${_optdir}"/chrome-sandbox || true

    # Exec
    install -dm755 "${pkgdir}"/usr/bin/
    ln -s /opt/${_pkgname}/${pkgname} "${pkgdir}"/usr/bin/

    # Menu
    install -Dm644 usr/share/applications/${pkgname}.desktop "${pkgdir}"/usr/share/applications/${pkgname}.desktop

    # Icons
    install -dm755 "${pkgdir}"/usr/share
    cp -dr --no-preserve=ownership usr/share/icons "${pkgdir}"/usr/share

    # License
    install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}