Package Details: x16-emulator-git r37.r0.g946284d-1

Git Clone URL: https://aur.archlinux.org/x16-emulator-git.git (read-only, click to copy)
Package Base: x16-emulator-git
Description: An emulator for The 8-Bit Guy's Commander X16
Upstream URL: http://commanderx16.com/
Licenses: BSD
Groups: commander-x16
Conflicts: x16-emulator
Provides: x16-emulator
Submitter: Juju
Maintainer: Juju
Last Packager: Juju
Votes: 0
Popularity: 0.000000
First Submitted: 2019-09-19 05:48
Last Updated: 2020-03-22 19:10

Required by (5)

Sources (2)

Latest Comments

FredBezies commented on 2021-09-21 09:42

Fixed PKGBUILD.

1) Right rom package is x16-rom-git

2) You cannot start the emulator without any roms, so x16-rom-git is added to depends.

3) You cannot build x16-emulator with gcc 11.1.x. See https://github.com/commanderx16/x16-emulator/issues/361 -> You have to use llvm instead.

# Maintainer: Julien Savard <juju@juju2143.ca>
pkgname=x16-emulator-git
pkgver=r38.r19.g8852ddd
pkgrel=1
pkgdesc="An emulator for The 8-Bit Guy's Commander X16"
arch=('x86_64')
url="http://commanderx16.com/"
license=('BSD')
groups=('commander-x16')
depends=('sdl2' 'x16-rom-git')
makedepends=('git' 'pandoc' 'gendesk' 'llvm' 'clang')
provides=('x16-emulator')
conflicts=('x16-emulator')
replaces=()
options=()
install=
changelog=
source=("git+https://github.com/commanderx16/x16-emulator.git")
sha256sums=('SKIP')

pkgver() {
    cd "${pkgname%-git}"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd "${pkgname%-git}"
    gendesk -f -n --pkgname "${pkgname%-git}" --pkgdesc "$pkgdesc" --name "X16 Emulator" --icon "${pkgname%-git}" --exec "x16emu" --categories "Game;Emulator"
}

build() {
    cd "${pkgname%-git}"
    # Working aroung bug: https://github.com/commanderx16/x16-emulator/issues/361
    export CC=clang
    export CXX=clang++
    export AR=llvm-ar
    export NM=llvm-nm
    export RANLIB=llvm-ranlib
    make
    pandoc --from gfm --to html -c github-pandoc.css --standalone --metadata pagetitle="X16 Emulator" README.md --output README.html
}

package() {
    cd "${pkgname%-git}"
    install -Dm755 x16emu "$pkgdir/usr/bin/x16emu"
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    install -Dm644 github-pandoc.css "$pkgdir/usr/share/doc/${pkgname%-git}/github-pandoc.css"
    install -Dm644 README.html "$pkgdir/usr/share/doc/${pkgname%-git}/README.html"
    install -Dm644 .gh/logo.png "$pkgdir/usr/share/pixmaps/${pkgname%-git}.png"
    install -Dm644 "${pkgname%-git}.desktop" "$pkgdir/usr/share/applications/${pkgname%-git}.desktop"
}

FredBezies commented on 2021-04-17 10:20

Patch is useless now:

==> Starting prepare()...
patching file main.c
Hunk #1 FAILED at 303.
patch: **** Can't reopen file main.c : No such file or directory