Package Details: xpadneo-dkms-git 0.9.r54.g7d1e6fd-4

Git Clone URL: https://aur.archlinux.org/xpadneo-dkms-git.git (read-only, click to copy)
Package Base: xpadneo-dkms-git
Description: Advanced Linux Driver for Xbox One Wireless Gamepad
Upstream URL: https://github.com/atar-axis/xpadneo
Licenses: GPL
Conflicts: xpadneo-dkms
Provides: xpadneo-dkms
Submitter: yangtsesu
Maintainer: joeleg
Last Packager: joeleg
Votes: 31
Popularity: 2.08
First Submitted: 2018-06-12 16:34
Last Updated: 2021-04-03 00:38

Latest Comments

1 2 3 Next › Last »

hero commented on 2021-04-02 21:37

As @laurentlaurent identified. There were some changes in the build that require some changes.

I used the following PKGBUILD to install the the current version:

# Maintainer: Joel Grunbaum <joel@joelg.net>
# Contributer: Yangtse Su <i@yangtse.me>
_pkgname=xpadneo
pkgname=xpadneo-dkms-git
pkgver=0.9.r54.g7d1e6fd
pkgrel=1
pkgdesc='Advanced Linux Driver for Xbox One Wireless Gamepad'
arch=('x86_64' 'armv7l')
url='https://github.com/atar-axis/xpadneo'
license=('GPL')
depends=('dkms' 'bluez' 'bluez-utils')
makedepends=('git')
conflicts=('xpadneo-dkms')
provides=('xpadneo-dkms')
source=('git+https://github.com/atar-axis/xpadneo.git')
sha256sums=('SKIP')

pkgver() {
    cd "${srcdir}/${_pkgname}"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

package() {
    cd "${srcdir}/${_pkgname}"

    echo "* replacing version string if necessary"
    sed -i 's/PACKAGE_VERSION="@DO_NOT_CHANGE@"/PACKAGE_VERSION="'${pkgver}'"/g' hid-xpadneo/dkms.conf.in
    mv hid-xpadneo/dkms.conf.in hid-xpadneo/dkms.conf

    sed -i 's/git describe --tags --dirty/echo "'${pkgver}'"/g' hid-xpadneo/Makefile

    sed -i 's@/etc/udev/rules\.d@/usr/lib/udev/rules\.d@g' hid-xpadneo/dkms.post_install
    sed -i 's@/etc/udev/rules\.d@/usr/lib/udev/rules\.d@g' hid-xpadneo/dkms.post_remove

    echo "* copying module into /usr/src"
    install -dm755 ${pkgdir}/usr/src/hid-xpadneo-${pkgver}
    cp --recursive $PWD/hid-xpadneo/* ${pkgdir}/usr/src/hid-xpadneo-${pkgver}
}

laurentlaurent commented on 2021-04-02 18:20 

==> Starting package()...
make: *** No rule to make target 'src/version.h'.  Stop.
==> ERROR: A failure occurred in package().
    Aborting...
:: Packages failed to build: xpadneo-dkms-git-0.9.r15.g9d8c4b7-2

This commit https://github.com/atar-axis/xpadneo/commit/7d1e6fde1ad6b26c65f851b15c25e8813c4e2acd broke the package.

katt commented on 2021-02-13 13:20

@daemon https://wiki.archlinux.org/index.php/Makepkg#Usage

deemon commented on 2021-02-12 17:13

==> ERROR: Cannot find the fakeroot binary. error making: xpadneo-dkms-git

joeleg commented on 2021-02-10 02:03

@pinsl: Sure, although I don't have a raspberry pi to test against, so I will be relying on you to let me know when something fails. Feel free to add yourself as a co-maintainer if you're willing

pinsl commented on 2021-02-09 20:42

Works fine on my raspberry pi 4. Maybe add at least armv7l to the arch variable in the pkgbuild?

l0b0 commented on 2021-01-29 07:05

@xrayfur: The package builds with the current latest commit, 6162dbc58a273b92b2ce854112b4250f3ea8dab0.

xrayfur commented on 2021-01-19 19:23 

==> Starting package()...
* replacing version string if necessary
sed: can't read hid-xpadneo/src/version.h: No such file or directory
==> ERROR: A failure occurred in package().
    Aborting...
error making: xpadneo-dkms-git

Package no longer builds due to error. Broken since commit: https://github.com/atar-axis/xpadneo/commit/581adfb222557aacb875c1529c88c9aaf13c6742

hero commented on 2020-11-15 18:20

The version information was moved into its own file (See this commit). So the PKGBUILD needs to be adapted. Also the version replacement can be simplified by using the already existing $pkgver. I use this PKGBUILD right now: https://gist.github.com/He-Ro/d23a6e64e880b8d30ed04ca3d3265dfd

mike_penner commented on 2020-11-13 20:45

After removing all traces of this package and the xpadneo-dkms package, I've been using this PKGBUILD with success.

_pkgname=xpadneo
pkgname=xpadneo-dkms-git
pkgver=0.8.r76.gde0c176
pkgrel=1
pkgdesc='Advanced Linux Driver for Xbox One Wireless Gamepad'
arch=('x86_64')
url='https://github.com/atar-axis/xpadneo'
license=('GPL')
depends=('dkms' 'bluez' 'bluez-utils' 'linux-headers')
makedepends=('git')
conflicts=('xpadneo-dkms')
provides=('xpadneo-dkms')
source=('git+https://github.com/atar-axis/xpadneo.git')
sha256sums=('SKIP')

pkgver() {
    cd "${srcdir}/${_pkgname}"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

package() {
    cd "${srcdir}/${_pkgname}"

    echo "* replacing version string if necessary"
    sed -i 's/PACKAGE_VERSION="@DO_NOT_CHANGE@"/PACKAGE_VERSION="'${pkgver}'"/g' hid-xpadneo/dkms.conf
    sed -i 's/#define DRV_VER "@DO_NOT_CHANGE@"/#define DRV_VER "'${pkgver}'"/g' hid-xpadneo/src/version.h

    sed -i 's@/etc/udev/rules\.d@/usr/lib/udev/rules\.d@g' hid-xpadneo/dkms.post_install
    sed -i 's@/etc/udev/rules\.d@/usr/lib/udev/rules\.d@g' hid-xpadneo/dkms.post_remove

    echo "* copying module into /usr/src"
    install -dm755 ${pkgdir}/usr/src/hid-xpadneo-${pkgver}
    cp --recursive $PWD/hid-xpadneo/* ${pkgdir}/usr/src/hid-xpadneo-${pkgver}
}