blob: 65ba0dfab885fe6e09e34ac23fbbac5d2863691b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: graysky <therealgraysky AT protonmail DOT com>
# Contributer: Bartłomiej Piotrowski <barthalion@gmail.com>
# Contributor: yugrotavele <yugrotavele at archlinux dot us>
# Contributor: Arkham <arkham at archlinux dot us>
# Contributor: Christoph Zeiler <archNOSPAM_at_moonblade.dot.org>
# Contributor: Arnaud Durand <biginozNOSPAM_at_free.dot.fr>
# Contributor: Nuno Araujo <nuno.araujo at russo79.com>
pkgname=bleachbit-cli
_pkgname=bleachbit
pkgver=4.6.0
pkgrel=2
pkgdesc='Deletes unneeded files to free disk space and maintain privacy. CLI version/no GUI.'
conflicts=($_pkgname)
provides=("bleachbit=${pkgver}")
arch=(any)
url='https://www.bleachbit.org/'
license=(GPL3)
depends=(python-gobject)
source=(https://github.com/bleachbit/bleachbit/archive/refs/tags/v$pkgver.tar.gz)
sha256sums=('6d32db1200fd6e89f0fa822e01ce8eaac9749e84788970b0f562d77b271db629')
package() {
cd $_pkgname-$pkgver
make prefix=/usr DESTDIR="$pkgdir" install
# to avoid cache getting generated by executable pre-build it which
# makes for a clean uninstall/update
python -m compileall -d /usr "$pkgdir"/usr
python -O -m compileall -d /usr "$pkgdir"/usr
# suggestion by Meow to force script to operate in cli mode
sed -i 's/if 1/if 0/' "$pkgdir"/usr/bin/bleachbit
rm -rf "$pkgdir"/usr/share/{applications,pixmaps}
rm -rf "$pkgdir"/usr/share/polkit-1
}
|