blob: cdb0276d3de6e48536cb92b37b635d70f2891b76 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Contributor: Patrick McCarty <pnorcks at gmail dot com>
pkgname=createrepo_c
pkgver=1.1.4
pkgrel=1
pkgdesc="A C implementation of createrepo, a tool to create yum repositories"
arch=('i686' 'x86_64')
license=('GPL-2.0-or-later')
url="https://github.com/rpm-software-management/$pkgname"
depends=('bzip2' 'curl' 'drpm>=0.4.0' 'glib2' 'libmodulemd>=2.3.0'
'libxml2' 'openssl' 'rpm-tools' 'sqlite>=3.6.18' 'xz' 'zchunk' 'zlib' 'zstd')
makedepends=('bash-completion' 'cmake>=3.13' 'doxygen'
'pkg-config' 'python' 'python-setuptools' 'python-sphinx')
optdepends=('python: for python bindings')
source=("$url/archive/$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('b4f020ef0400e3f9840d37d16238bda2b529b47749dcea6f43c9038056c64669')
build() {
cd "$pkgname-$pkgver"
cmake -B build \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_C_FLAGS_RELEASE='-DNDEBUG' \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DENABLE_BASHCOMP=ON \
-DENABLE_DRPM=ON \
-DENABLE_PYTHON=ON \
-DWITH_LEGACY_HASHES=ON \
-DWITH_LIBMODULEMD=ON \
-DWITH_ZCHUNK=ON \
-Wno-dev
cmake --build build
cmake --build build --target doc
}
check() {
cd "$pkgname-$pkgver"
cmake --build build --target tests
ctest --test-dir build --output-on-failure
}
package() {
cd "$pkgname-$pkgver"
DESTDIR="$pkgdir" cmake --install build
install -Dp -m644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
cp -Rp examples "$pkgdir/usr/share/doc/$pkgname"
}
# vim: set ft=sh ts=4 sw=4 noet:
|