summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: dd8fb07396e085dc7c7d8a94e01a0a0008c4b7a5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer: Anatol Pomozov
# Contributor: Thomas Krug <t.krug@elektronenpumpe.de>

pkgname=dsview-git
pkgver=0.98.r9.gb31f432
pkgrel=1
pkgdesc='GUI programe for supporting various instruments from DreamSourceLab, including logic analyzer, oscilloscope, etc.'
arch=(i686 x86_64)
url='http://www.dreamsourcelab.com/'
license=(GPL3)
# Upstream added VCS dependency to libsigrokdecode :/
depends=(boost-libs qt5-base fftw libsigrok4dsl-git libsigrokdecode4dsl-git)
makedepends=(boost cmake)
source=(git://github.com/DreamSourceLab/DSView) #branch=develop
sha1sums=('SKIP')

pkgver() {
  cd DSView
  git describe --long | sed -r 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}

prepare() {
  cd DSView/DSView
  sed 's|/usr/local/|/usr/|' -i DSView.desktop
}

build() {
  cd DSView/DSView

  cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  cd DSView/DSView

  make DESTDIR="$pkgdir" install
  #install -Dm644 icons/logo_color.png "$pkgdir/usr/share/pixmaps/dsview.png"
}