blob: ade0c3bee4550c886f90fc38c9eb948f106bc2d4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Jonian Guveli <https://github.com/jonian/>
pkgname=gnome-shell-extension-bluetooth-quick-connect
_uuid=bluetooth-quick-connect@bjarosze.gmail.com
pkgver=53
pkgrel=1
pkgdesc="Allow to connect Bluetooth paired devices from GNOME control panel."
arch=('any')
url="https://github.com/Extensions-Valhalla/gnome-bluetooth-quick-connect"
license=('GPL-3.0-or-later')
depends=(
'bluez-utils'
'gnome-shell'
)
makedepends=(
'pnpm'
'zip'
)
source=("gnome-bluetooth-quick-connect-v$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('a9ef201786e3189d84e7dc2ff70e0f7d083fdce65a8d20eed064e9ae649095c4')
build() {
cd gnome-bluetooth-quick-connect-$pkgver
export PNPM_HOME="$srcdir/pnpm-home"
pnpm install
pnpm build
}
package() {
cd gnome-bluetooth-quick-connect-$pkgver
install -d "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}"
bsdtar -xvf "dist/${_uuid}.shell-extension.zip" -C \
"$pkgdir/usr/share/gnome-shell/extensions/${_uuid}/" --no-same-owner
mv "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}/locale" "$pkgdir/usr/share"
install -Dm644 dist/schemas/org.gnome.shell.extensions.bluetooth-quick-connect.gschema.xml -t \
"$pkgdir/usr/share/glib-2.0/schemas/"
rm -rv "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}/schemas"
}
|