blob: 9a66fad1bfde52de148860091c14b080acec2747 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
# Thanks: Forest Crossman <cyrozap at gmail dot com>
# Maintainer: Annoyedmilk <hello@annoyedmilk.ch>
# Contributor: ResRipper <resripper@connective.link>
# Contributor: Stephanie Wilde-Hobbs <gpg@stephanie.is>
# shellcheck disable=SC2034,SC2154,SC2148
pkgname=go-configure-sw-hub
_pkgver_major=6.55
_pkgver_minor=001
pkgver=$_pkgver_major.$_pkgver_minor
pkgrel=1
pkgdesc="Renesas/Dialog/Silego Go Configure software hub (greenpak designer)"
arch=('x86_64')
url="https://www.renesas.com/us/en/software-tool/go-configure-software-hub"
license=('custom:Go_Configure_Software_Hub_Software_Licensing_Agreement')
depends=(
alsa-lib
dbus
desktop-file-utils
expat
fontconfig
freetype2
gcc-libs
glib2
graphviz
hicolor-icon-theme
krb5
libcups
libdrm
libglvnd
libxshmfence
libx11
libxcb
libxcomposite
libxdamage
libxext
libxfixes
libxi
libxkbcommon
libxkbcommon-x11
libxkbfile
libxrandr
libxrender
libxtst
nspr
nss
shared-mime-info
systemd-libs
xcb-util-cursor
xcb-util-image
xcb-util-keysyms
xcb-util-renderutil
xcb-util-wm
zlib
)
makedepends=(patchelf)
conflicts=('greenpak-designer-dev' 'greenpak-designer')
replaces=('greenpak-designer-dev' 'greenpak-designer')
options=('!strip' '!debug')
source=("https://renesasweb-greenpak.s3.us-west-2.amazonaws.com/v${_pkgver_major}/go-configure-sw-hub-v${pkgver}-debian-13-amd64.deb")
b2sums=('3f0d2c6473922d4923bbb3619db65869e8ecd141130bd5b7a3e3775e3eb6e32e6b387dac0c93e3d86ea3aa6ad6fc816f0ef56f2ca1c815f9aef4e22acf9e142e')
package() {
# Extract the package data
tar -xf data.tar.xz -C "${pkgdir}"/
# Install udev rules
install -dm 755 "${pkgdir}/usr/lib/udev/rules.d"
mv "${pkgdir}"/lib/udev/rules.d/* "${pkgdir}"/usr/lib/udev/rules.d
rm -r "${pkgdir}"/lib
# Move package to /opt
install -dm 755 "${pkgdir}"/opt
mv "${pkgdir}"/usr/local/"${pkgname}" "${pkgdir}"/opt/"${pkgname}"
rm -r "${pkgdir}"/usr/local
# Link launcher to /usr/bin
rm "${pkgdir}"/usr/bin/*
ln -s /opt/${pkgname}/bin/GPLauncher "${pkgdir}"/usr/bin/GPLauncher
# Fix desktop launchers
for _launcher in "${pkgdir}/usr/share/applications"/*.desktop; do
sed -i -e "s!local/${pkgname}/!!g" "$_launcher"
done
# Install license file
install -dm 755 "${pkgdir}/usr/share/licenses/${pkgname}"
ln -s "/usr/share/doc/${pkgname}/copyright" "${pkgdir}/usr/share/licenses/${pkgname}/copyright"
# Patch graphviz sonames — app was built against an older graphviz (soname 6),
# Arch ships soname 7/10. Only GP5 and GP6 link against graphviz.
for _bin in GP5 GP6; do
patchelf --replace-needed libgvc.so.6 libgvc.so.7 "${pkgdir}/opt/${pkgname}/bin/${_bin}"
patchelf --replace-needed libcgraph.so.6 libcgraph.so.10 "${pkgdir}/opt/${pkgname}/bin/${_bin}"
done
}
|