summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 81b8f3c6a73ed74e3dda8585c709cc05340405e2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: Christopher Arndt <chris@chrisarndt.de>
# Contributor: speps <speps at aur dot archlinux dot org>
# Contributor: Peter Crighton <petecrighton@googlemail.com>

_pkgname=liblscp
pkgname="${_pkgname}-svn"
pkgver=0.5.7.1.2923
pkgrel=1
pkgdesc="LinuxSampler Control Protocol (LSCP) wrapper library"
arch=('i686' 'x86_64')
url="http://www.linuxsampler.org/"
license=('LGPL')
depends=('glibc')
makedepends=('subversion' 'doxygen' 'libtool')
conflicts=("${_pkgname}")
provides=("${_pkgname}")
options=('!libtool')
source=("${_pkgname}::svn+https://svn.linuxsampler.org/svn/${_pkgname}/trunk")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/${_pkgname}"

  echo $(sed -n 's/AM_INIT_AUTOMAKE.*, \(.*\))/\1/p' configure.ac).$(svnversion)
}

build() {
  cd "$srcdir/${_pkgname}"

  make -f Makefile.svn
  ./configure --prefix=/usr \
              --enable-static=no
  make
}

package() {
  cd "$srcdir/${_pkgname}"

  make DESTDIR="$pkgdir/" install
}