blob: 8e53831feab9dc4744a7ee0bd7f41b07faccb53b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: pingplug < aur at pingplug dot me >
# Contributor: Schala Zeal < schalaalexiazeal at gmail dot com >
# Contributor: Xiao-Long Chen < chenxiaolong at cxl dot epac dot to >
_commit=3909090108bb2db55330e3eb148aebe664735363 # tags/1.18.0^0
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
pkgname=mingw-w64-cairo
pkgver=1.18.0
pkgrel=2
pkgdesc="2D graphics library with support for multiple output devices (mingw-w64)"
arch=('any')
url="https://cairographics.org"
license=('LGPL' 'MPL')
depends=('mingw-w64-fontconfig'
'mingw-w64-pixman'
'mingw-w64-libpng'
'mingw-w64-lzo'
'mingw-w64-glib2')
makedepends=('git'
'mingw-w64-meson'
'mingw-w64-librsvg'
'mingw-w64-poppler')
conflicts=("${pkgname}-bootstrap")
replaces=("${pkgname}-bootstrap")
options=('!strip' '!buildflags' 'staticlibs')
source=("git+https://gitlab.freedesktop.org/cairo/cairo.git#commit=${_commit}"
"0026-create-argb-fonts.all.patch")
sha256sums=('SKIP'
'6db6c44fbdb4926d09afa978fe80430186c4b7b7d255059602b1f94c6a079975')
pkgver() {
cd "${srcdir}/cairo"
git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}
prepare() {
cd "${srcdir}/cairo"
patch -p1 -i ${srcdir}/0026-create-argb-fonts.all.patch
}
build() {
cd "${srcdir}"
for _arch in ${_architectures}; do
${_arch}-meson cairo build-${_arch} \
--buildtype=release \
--default-library=both \
-D b_lto=false \
-D dwrite=disabled \
-D freetype=enabled \
-D fontconfig=enabled \
-D gtk_doc=false \
-D spectre=disabled \
-D symbol-lookup=disabled \
-D tests=disabled
meson compile -C build-${_arch}
done
}
package() {
cd "${srcdir}"
for _arch in ${_architectures}; do
meson install -C build-${_arch} --destdir "${pkgdir}"
${_arch}-strip --strip-unneeded "${pkgdir}"/usr/${_arch}/bin/*.dll
${_arch}-strip -g "${pkgdir}"/usr/${_arch}/lib/*.a
done
}
# vim:set ts=2 sw=2 et:
|