PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Contributor: Rasi <rasi@xssn.at>
# Maintainer: aksr <aksr at t-com dot me>
pkgname=ncmpc-git
pkgver=0.34.1.g93dcece
pkgrel=1
pkgdesc="A fully featured MPD client, which runs in a terminal (using ncurses)."
arch=('i686' 'x86_64')
url="http://www.musicpd.org/clients/ncmpc/"
license=('GPL')
depends=('ncurses' 'glib2' 'libmpdclient' 'python' 'expat')
makedepends=('git' 'meson')
conflicts=('ncmpc' 'ncmpc-svn')
source=("$pkgname::git+https://github.com/MusicPlayerDaemon/ncmpc.git")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$pkgname"
  git describe --always | sed 's/^v//g;s|-|.|g'
}

build() {
  cd "$srcdir/$pkgname"
  meson --prefix /usr . output
  meson configure -Dasync_connect=true \
                  -Dchat_screen=true \
                  -Dcolors=false \
                  -Dhelp_screen=true \
                  -Dkey_screen=true \
                  -Dlibrary_screen=true \
                  -Dlirc=auto \
                  -Dlocale=auto \
                  -Dlyrics_screen=true \
                  -Dmanual=true \
                  -Dmouse=enabled \
                  -Dmultibyte=true \
                  -Dnls=auto \
                  -Doutputs_screen=true \
                  -Dregex=enabled \
                  -Dsearch_screen=true \
                  -Dsong_screen=true output
}

package() {
  cd "$srcdir/$pkgname"
  DESTDIR=$pkgdir ninja -C output install
  rm $pkgdir/usr/share/doc/${pkgname%-*}/{AUTHORS,COPYING,NEWS}
  install -Dm644 COPYING $pkgdir/usr/share/licenses/${pkgname%-*}/COPYING
}