PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Maintainer: Daniel Bermond <dbermond@archlinux.org>

pkgname=openshot-git
pkgver=3.5.0.r84.gc13495c9a
pkgrel=1
pkgdesc='An award-winning free and open-source video editor (git version)'
arch=('any')
url='https://www.openshot.org/'
license=('GPL-3.0-or-later')
depends=(
    'ffmpeg'
    'hicolor-icon-theme'
    'libopenshot-audio-git'
    'libopenshot-git'
    'python'
    'python-pyqt5'
    'python-pyqt5-webengine'
    'python-pyzmq'
    'python-requests'
    'qt5-base'
    'qt5-svg')
optdepends=(
    'faac: for exporting audio using AAC')
makedepends=(
    'git'
    'python-build'
    'python-installer'
    'python-setuptools'
    'python-wheel')
checkdepends=(
    'xorg-server-xvfb')
provides=('openshot')
conflicts=('openshot')
source=('git+https://github.com/OpenShot/openshot-qt.git')
sha256sums=('SKIP')

pkgver() {
    git -C openshot-qt describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}

build() {
    cd openshot-qt
    python -m build --wheel --no-isolation
}

check() {
    cd openshot-qt
    xvfb-run -n 71 python src/tests/test_query.py
}

package() {
    python -m installer --destdir="$pkgdir" openshot-qt/dist/*.whl
}