blob: 70c29ef82d0c83f76ae74b85dde87485d7e219e5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Philipp Wolfer <ph.wolfer@gmail.com>
_pkgname=peek
pkgname=${_pkgname}-git
pkgver=1.5.1.r1.ga6a0bcf
pkgrel=1
pkgdesc="Simple screen recorder with an easy to use interface (latest development release)"
arch=('i686' 'x86_64')
url="https://github.com/phw/peek"
license=('GPL3')
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}")
depends=(gtk3 libkeybinder3 ffmpeg)
makedepends=(git meson vala gettext txt2man)
checkdepends=(xorg-server-xvfb)
optdepends=(
'gst-plugins-good: Recording under Gnome Shell'
'gst-plugins-ugly: MP4 output under Gnome Shell'
'gifski: High quality GIF animations with thousands of colors'
)
source=(git+https://github.com/phw/${_pkgname}.git)
sha1sums=('SKIP')
build() {
cd "${srcdir}/${_pkgname}"
meson \
--prefix=/usr \
--buildtype=release \
-Denable-filechoosernative=true \
builddir
cd builddir
ninja
}
check() {
cd "${srcdir}/${_pkgname}/builddir"
xvfb-run ninja test
}
package() {
cd "${srcdir}/${_pkgname}/builddir"
DESTDIR=${pkgdir} ninja install
}
pkgver() {
cd "${srcdir}/${_pkgname}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
|