PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer:
# Contributor: Sebastian Lau <lauseb644@gmail.com>

pkgname='python-omr'
_module='omr'
pkgdesc="Extract answer choices from scanned jpg bubble forms"
pkgver='0.0.73'
pkgrel=3
# http://github.com/GregoryCMiller/omr
url='https://pypi.org/project/omr'
arch=('any')
license=('unknown')

depends=(
  'python-numpy'
  'python-openpyxl'
  'python-pillow'
  'python-setuptools'
  'python-yaml'
)
makedepends=(
  'python-build'
  'python-installer'
  'python-wheel'
)

source=(
  "https://files.pythonhosted.org/packages/source/${_module::1}/$_module/$_module-$pkgver.tar.gz"
)
sha256sums=(
  '8feca62c1ceab22aeebe74533960f51d32813943195ba0f05dc73f1e3231374f'
)

prepare() {
  cd "$srcdir/$_module-$pkgver"
  2to3 -w */*.py
}

build() {
  cd "$srcdir/$_module-$pkgver"
  python -m build --no-isolation --wheel
}

package() {
  cd "$srcdir/$_module-$pkgver"
  python -m installer --destdir="$pkgdir" dist/*.whl
}