summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: a9ebb21d845e0785cdd29f3ebee5166695aa44be (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer: Andy Weidenbaum <archbaum@gmail.com>

pkgname=snooze-git
pkgver=20160105
pkgrel=1
pkgdesc="Run a command at a particular time"
arch=('i686' 'x86_64')
makedepends=('git' 'make')
url="https://github.com/chneukirchen/snooze"
license=('CC0')
source=(git+https://github.com/chneukirchen/snooze)
sha256sums=('SKIP')
provides=('snooze')
conflicts=('snooze')

pkgver() {
  cd ${pkgname%-git}
  git log -1 --format="%cd" --date=short --no-show-signature | sed "s|-||g"
}

build() {
  cd ${pkgname%-git}

  msg2 'Building...'
  make
}

package() {
  cd ${pkgname%-git}

  msg2 'Installing documentation...'
  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/snooze"

  msg2 'Installing...'
  make PREFIX=/usr DESTDIR="$pkgdir" install

  msg2 'Cleaning up pkgdir...'
  find "$pkgdir" -type d -name .git -exec rm -r '{}' +
}