summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6bb4eafe6d32b7130efc3765b2316753a453b435 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
# Maintainer: skydrome
# Contributor: IgnorantGuru http://igurublog.wordpress.com/contact-ignorantguru/

GTK=3

pkgname=spacefm-git
pkgver=1.0.6.r80.ge257d15
pkgrel=1
pkgdesc="A multi-panel tabbed file manager - git branch"
arch=('i686' 'x86_64')
url="https://ignorantguru.github.io/spacefm"
license=('GPL3')
conflicts=("spacefm")
provides=("spacefm")
makedepends=('intltool' 'gettext')
depends=('startup-notification' 'ffmpegthumbnailer' 'hicolor-icon-theme' 'shared-mime-info' 'desktop-file-utils' 'cairo' 'pango' 'udevil' 'udisks2')
optdepends=('dbus: dbus integration'
            'util-linux: disk eject support'
            'lsof: device processes'
            'wget: plugin download'
            'gksu: perform as root functionality'
            'udevil: mount as non-root user and mount networks'
            'udisks2: mount as non-root user'
            'pmount: mount as non-root user'
            'curlftpfs: mount FTP shares'
            'jmtpfs: mount MTP devices'
            'gphotofs: mount cameras'
            'ifuse: mount your iPhone/iPod Touch'
            'fuseiso: mount ISO files')

if [[ "$GTK" = 2 ]]; then
    depends+=('gtk2'); _opts='--with-gtk2'
else
    depends+=('gtk3'); _opts='--with-gtk3'
fi

source=("git+https://github.com/IgnorantGuru/spacefm.git#branch=alpha"
        "glibc_2.28.patch")
sha256sums=('SKIP'
            '12411055df994211d2968cb52746b6caefce6926aed1ed33b542bd70b571ce7e')

pkgver() {
    cd "spacefm"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd "spacefm"
    patch -Np1 -i ../glibc_2.28.patch
    ./autogen.sh --prefix=/usr "$_opts"
}

build() {
    cd "spacefm"
    make
}

package() {
    cd "spacefm"
    make DESTDIR="$pkgdir" install
    rm -f "$pkgdir"/usr/bin/spacefm-installer
}