PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# PKGBUILD for ag
# Maintainer: Allen Wild <allenwild93 at gmail dot com>

pkgdesc="Allen Wild's fork of ag, which supports pcre2 and .agrc user config"
url='https://github.com/aswild/the_silver_searcher'
pkgname=the_silver_searcher_wild-git
pkgver=2.2.0.r195.gab8bbc3
pkgrel=1
provides=('the_silver_searcher')
conflicts=('the_silver_searcher')

arch=('x86_64' 'i686')
license=('Apache')

depends=('pcre2' 'xz' 'zlib' 'libarchive')
makedepends=('git')
checkdepends=('python-cram')

_srcname="the_silver_searcher"
source=("git://github.com/aswild/${_srcname}.git")
md5sums=('SKIP')

pkgver() {
    cd "$srcdir/$_srcname"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "$srcdir/$_srcname"
    ./autogen.sh
    ./configure --prefix=/usr \
                --enable-zlib \
                --enable-lzma \
                --enable-libarchive \
                ac_cv_prog_CLANG_FORMAT=no
    make
}

check() {
    cd "$srcdir/$_srcname"
    make check
}

package() {
    cd "$srcdir/$_srcname"
    make DESTDIR="$pkgdir/" install
}