Arch Linux User Repository

@joe1984 The README of the project has a notice saying 64-bit builds tend to produce faulty images.

@bemxio How are the 64 builds broken? I'm able to create and extract archives just fine?

@bemxio The license is BSD-4-Clause.

But anyway, I pushed a commit based on your changes. Thanks!

Hello! I have refactored the PKGBUILD a little bit, so that it fits more into AUR guidelines. I used the SPDX license identifier, made it get the source files from a tarball instead, removing the git dependency and forced it to compile in 32-bit, because it seems like the 64-bit builds are broken.

# Maintainer: begin-theadventure <begin-thecontact.ncncb at dralias dot com>
# Contributor: Joe Carta <cartakid at gmail dot com>
# Contributor: sidious/SiD <miste78 at web dot de>
# Contributor: Wes Brewer <brewerw at gmail dot com>
# Contributor: bemxio <bemxiov at protonmail dot com>

pkgname="extract-xiso"
pkgdesc="Xbox ISO creation/extraction utility"

pkgver=202303040307
pkgrel=3

arch=(x86_64 i686)

url="https://github.com/XboxDev/extract-xiso"
license=("BSD-3-Clause")

depends=(lib32-glibc)
makedepends=(cmake)

provides=(extract-xiso)
conflicts=(extract-xiso-git)

source=("https://github.com/XboxDev/extract-xiso/archive/refs/tags/build-${pkgver}.tar.gz")
md5sums=("1aeb7f161a7687b7fbbeb579332791eb")

prepare() {
    # move into the source directory
    cd "extract-xiso-build-${pkgver}"

    # create a build directory
    mkdir -p build && cd build

    # generate a Makefile
    cmake .. -DCMAKE_BUILD_TYPE=Release -DCMAKE_C_FLAGS=-m32
}

build() {
    # move into the source directory
    cd "extract-xiso-build-${pkgver}"

    # move into the build directory
    cd build

    # build the project
    make
}

package() {
    # move into the source directory
    cd "extract-xiso-build-${pkgver}"

    # copy the main executable and the license
    install -Dm755 build/extract-xiso "${pkgdir}/usr/bin/extract-xiso"
    install -Dm644 LICENSE.TXT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

Works 👍

Thank you @PQCraft, it should be fixed now.

Getting this when building:

==> Starting prepare()...
Note: switching to 'tags/build-202303040307'.

You are in 'detached HEAD' state. You can look around, make experimental
changes and commit them, and you can discard any commits you make in this
state without impacting any branches by switching back to a branch.

If you want to create a new branch to retain commits you create, you may
do so (now or later) by using -c with the switch command. Example:

  git switch -c <new-branch-name>

Or undo this operation with:

  git switch -

Turn off this advice by setting config variable advice.detachedHead to false

HEAD is now at 3438285 Use strcasecmp when useful
==> Sources are ready.
==> Making package: extract-xiso 202303040307-1 (Sat 03 Jun 2023 11:24:02 AM EDT)
==> Checking runtime dependencies...
==> Checking buildtime dependencies...
==> WARNING: Using existing $srcdir/ tree
==> Starting build()...
make: *** No targets specified and no makefile found.  Stop.
==> ERROR: A failure occurred in build().
    Aborting...
 -> error making: extract-xiso-exit status 4
 -> Failed to install the following packages. Manual intervention is required:
extract-xiso - exit status 4

I changed arch, thanks, as for git checkout, is it forbidden on the AUR?

Please set the tag in source instead of using git checkout...

Also arch=('any') is wrong here since the produced binaries will be compiled for a specific architecture.

This tool is known to be broken, and this package is configured in such a way where the resulting build WILL create corrupt ISO images if they are over a certain size. I strongly recommend switching to xdvdfs instead.