Package Details: freshplayerplugin-git 0.3.11.r4.g0f46d4a-1

Git Clone URL: https://aur.archlinux.org/freshplayerplugin-git.git (read-only, click to copy)
Package Base: freshplayerplugin-git
Description: PPAPI-host NPAPI-plugin adapter.
Upstream URL: https://github.com/i-rinat/freshplayerplugin
Licenses: MIT
Conflicts: freshplayerplugin
Submitter: Behem0th
Maintainer: WorMzy
Last Packager: WorMzy
Votes: 147
Popularity: 0.000000
First Submitted: 2014-03-31 20:10 (UTC)
Last Updated: 2023-12-29 21:38 (UTC)

Latest Comments

1 2 3 4 5 6 .. 13 Next › Last »

sl1pkn07 commented on 2023-11-05 06:39 (UTC) (edited on 2023-11-05 06:40 (UTC) by sl1pkn07)

lets hack (for build)

# Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
# Contributor: Jack L. Frost <fbt@fleshless.org>
# Contributor: Corelli <corelli AT sent DOT com>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: intelfx <intelfx100 [at] gmail [dot] com>
# Contributor: Behem0th <grantipak@gmail.com> 
# Contributor: zman0900 <zman0900@gmail.com>

pkgname=freshplayerplugin-git
pkgver=0.3.11.4.g0f46d4a
pkgrel=1
pkgdesc='PPAPI-host NPAPI-plugin adapter. (GIT version)'
arch=('x86_64')
url='https://github.com/i-rinat/freshplayerplugin'
license=('MIT')
depends=(
  'gcc-libs' # libgcc_s.so libstdc++.so
  'glibc' # libc.so libm.so
  'pango' 'libpango-1.0.so' 'libpangocairo-1.0.so' 'libpangoft2-1.0.so'
  'cairo' # libcairo.so
  'alsa-lib' 'libasound.so'
  'libva' 'libva-x11.so' 'libva.so'
  'libvdpau' 'libvdpau.so'
  'libpulse' 'libpulse.so'
  'libsoxr' # libsoxr.so
  'jack2' 'libjack.so'
  'freetype2' # libfreetype.so
  'libevent' 'libevent-2.1.so' 'libevent_pthreads-2.1.so'
  'libglvnd' 'libGL.so'
  'v4l-utils' # libv4l2.so
  'icu' # libicuuc.so
  'libxrandr' # libXrandr.so
  'libxcursor' # libXcursor.so
  'libxrender' # libXrender.so
  'libx11' # libX11.so
  'glib2' 'libgio-2.0.so' 'libglib-2.0.so' 'libgobject-2.0.so'
  'zlib' 'libz.so'
  'openssl' 'libcrypto.so'
  'pepper-flash'
)
makedepends=(
  'cmake'
  'ragel'
  'git'
)
conflicts=('freshplayerplugin')
provides=('freshplayerplugin')
source=(
  'git+https://github.com/i-rinat/freshplayerplugin.git'
  'https://ffmpeg.org/releases/ffmpeg-1.2.12.tar.bz2'
  'mathops_fix.patch::https://git.videolan.org/?p=ffmpeg.git;a=patch;h=effadce6c756247ea8bae32dc13bb3e6f464f0eb'
)
sha256sums=(
  'SKIP'
  '913ac95c7fad92c2a4ebcfd11850904f531845c75d45c3e4e4a693990fe2497d'
  'a50d7da9870a3fd801ad3a4d13d5c9b260acb094cf8bfa4afd95a54741173a7f'
)

pkgver() {
  cd freshplayerplugin
  echo "$(git describe --long --tags | tr - . | tr -d v)"
}

build() {
  cd ffmpeg-1.2.12
  patch -p1 -i "${srcdir}/mathops_fix.patch"
  ./configure \
    --prefix="${srcdir}/fakeroot" \
    --enable-libpulse \
    --enable-indev=alsa,pulse,oss,fbdev \
    --enable-outdev=alsa,pulse,oss,fbdev \
    --disable-programs \
    --disable-doc

  make
  make install
  cd ..

  export PKG_CONFIG_LIBDIR="${srcdir}/fakeroot/lib/pkgconfig"
  export PKG_CONFIG_PATH="${PKG_CONFIG_LIBDIR}:/usr/lib/pkgconfig:/usr/share/pkgconfig"
  cmake -S freshplayerplugin -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr

  cmake --build build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build

  install -Dm644 freshplayerplugin/data/freshwrapper.conf.example "${pkgdir}/usr/share/${pkgname}/freshwrapper.conf.example"
  install -Dm644 freshplayerplugin/LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

WorMzy commented on 2016-10-14 16:22 (UTC)

Sorry Scimmia, missed your original message. I'll fix this up now.

Scimmia commented on 2016-10-14 15:53 (UTC)

And now google-chrome doesn't include the plugin either...

Scimmia commented on 2016-09-22 23:55 (UTC)

Optional deps really need fixed here. chromium-pepper-flash{,-standalone} no longer exist, and google-chrome-{beta,dev} don't include the plugin.

WorMzy commented on 2016-06-03 18:27 (UTC)

Cheers!

<deleted-account> commented on 2016-06-03 15:08 (UTC)

Adopt the package and do whatever you like with it.

WorMzy commented on 2016-06-03 09:27 (UTC)

icu needs to be added to the depends array. Upstream still builds against gtk2 by default, so please revert the switch to gtk3 builds.

WorMzy commented on 2016-03-11 09:59 (UTC)

Why does this deviate from upstream and build with gtk3 by default? Please revert this change.

maciejjo commented on 2015-10-12 23:59 (UTC)

No I haven't, I have only core/binutils installed.

WorMzy commented on 2015-10-12 21:28 (UTC)

No, ncurses 5 isn't needed for this package. Have you replaced your binutils with an AUR package?

1 2 3 4 5 6 .. 13 Next › Last »