Package Details: gtk4-layer-shell 1.0.2-2

Git Clone URL: https://aur.archlinux.org/gtk4-layer-shell.git (read-only, click to copy)
Package Base: gtk4-layer-shell
Description: A library to create panels and other desktop components for Wayland using the Layer Shell protocol and GTK4
Upstream URL: https://github.com/wmww/gtk4-layer-shell
Licenses: MIT
Submitter: SilverRainZ
Maintainer: SilverRainZ
Last Packager: SilverRainZ
Votes: 6
Popularity: 0.86
First Submitted: 2023-04-28 16:15 (UTC)
Last Updated: 2023-11-25 04:04 (UTC)

Latest Comments

SilverRainZ commented on 2023-11-24 11:37 (UTC)

@pentamassiv updated

pentamassiv commented on 2023-09-21 21:50 (UTC)

Could you please update the PKGBUILD to the following:

# Maintainer: Shengyu Zhang <la@archlinuxcn.org>
# Contributor: Brett Cornwall <ainola@archlinux.org>
# Contributor: Adrian Perez de Castro <aperez@igalia.com>

pkgdesc='A library to create panels and other desktop components for Wayland using the Layer Shell protocol and GTK4'
pkgname=gtk4-layer-shell
pkgver=1.0.1
pkgrel=1
arch=(x86_64 aarch64)
license=(MIT)
url="https://github.com/wmww/gtk4-layer-shell"
depends=(
    "gtk4"
    "wayland"
)
makedepends=(
    "gtk-doc"
    "gobject-introspection"
    "meson"
    "ninja"
    "valabind"
    "python"
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('f7b8d352065a540d4cb7b0cbfdeb2c2efea55b57cfb717de5c880fde41e65cb1')

build() {
    meson setup \
          --prefix=/usr \
          --wrap-mode=nofallback \
          --buildtype=plain \
          -Dtests=true \
          -Ddocs=true \
          -Dintrospection=true \
          -Dvapi=true \
          -Dexamples=true \
          "$pkgname-$pkgver" \
          build
    ninja -C build
}

# See: https://github.com/wmww/gtk4-layer-shell/issues/12
# check() {
# ninja -C build test
# }

package() {
    DESTDIR="$pkgdir" ninja -C build install
    install -D -m 644 "$pkgname-$pkgver/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

pentamassiv commented on 2023-08-03 22:35 (UTC)

The package also works on my Pinephone (aarch64), so could you please change the line arch=(x86_64) to arch=(any)?

pentamassiv commented on 2023-08-03 17:18 (UTC)

Version 1.0.1 was released, which contains the fix

stbowers commented on 2023-06-13 20:20 (UTC)

In the mean time, if you want to install this alongside extra/gtk-layer-shell before the developer makes a new release with this fix, you can manually apply the patch with the following modification to the PKGBUILD:

--- gtk4-layer-shell.PKGBUILD.original  2023-06-13 13:59:24.000000000 -0600
+++ gtk4-layer-shell.PKGBUILD   2023-06-13 14:06:36.340988132 -0600
@@ -21,8 +21,15 @@
     "valabind"
     "python"
 )
-source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
-sha256sums=('89d25ca0a7c2db7795c6bfb46e7d504ee71f005b3ea8580c8e9e35b57027be92')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz"
+        "14.patch::$url/pull/14.patch")
+sha256sums=('89d25ca0a7c2db7795c6bfb46e7d504ee71f005b3ea8580c8e9e35b57027be92'
+            '6260a4947890f9d30f0a2f4ad445925503234dfeb27d7848c836816855973f98')
+
+prepare() {
+    cd "$pkgname-$pkgver"
+    patch --strip=1 --input="${srcdir}/14.patch"
+}

 build() {
     meson --prefix=/usr \

zefr0x commented on 2023-06-05 17:36 (UTC) (edited on 2023-06-05 17:40 (UTC) by zefr0x)

This conflict with extra/gtk-layer-shell, since both of them use the same /usr/share/gtk-doc/html/gtk-layer-shell/ directory for docs.

Edit: It has been fixed in https://github.com/wmww/gtk4-layer-shell/commit/e4d09108dbd607b45a84cf3e76b93be919043db9 but not released.