Arch Linux User Repository

This AUR repo has switched to a build-from-source package.

However, binary version can be found as logisim-evolution-bin.

logisim-evolution-3.4.5-1

# Maintainer: maniacata <maniaciachao at gmail dot com>
# Contributor: Marcin Wieczorek <marcin@marcin.co>
# Contributor: Martin Thierer <thierer@web.de>
# Contributor: Amy Wilson <awils_1[at]xsmail[dot]com>
# Contributor: Simon Doppler <dopsi[at]dopsi[dot]ch>
# Contributor: Agustin Borgna <hello[at]aborgna.com.ar>
# Contributor: Marcel Korpel <marcel[dot]korpel[at]gmail>
# Contributor: Renan Birck <renan.ee.ufsm at gmail.com>

pkgname=logisim-evolution
pkgver=3.4.5
pkgrel=1
pkgdesc='An educational tool for designing and simulating digital logic circuits (build from source)'
provides=('logisim-evolution')
conflicts=('logisim-evolution-git' 'logisim-evolution-bin')
arch=('any')
url="https://github.com/reds-heig/logisim-evolution"
license=('GPL3')
depends=('java-runtime>=9' 'hicolor-icon-theme')
makedepends=('java-environment>=9')

source=("${pkgname}-${pkgver}.tar.gz::https://github.com/reds-heig/logisim-evolution/archive/refs/tags/V${pkgver}.tar.gz"
        "${pkgname}.sh")
sha256sums=('0ecec082d4bdfae2ad1b579d5e001e736ed2445a983b1c78201e80c0cebfd3e3'
            'd5975cc0025905ab8a8a451ce4362ba876bed88008d3a5b2c0a7f664a85da1ba')

install=$pkgname.install

build() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    ./gradlew shadowJar
}

package() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    install -Dm644 "build/libs/logisim-evolution-${pkgver}-all.jar" \
                   "${pkgdir}/usr/share/java/${pkgname}/${pkgname}.jar"
    install -Dm644 "support/Flatpak/com.github.reds.LogisimEvolution.xml" \
                   "${pkgdir}/usr/share/mime/packages/${pkgname}.xml"
    install -Dm644 "support/Flatpak/com.github.reds.LogisimEvolution.desktop" \
                   "${pkgdir}/usr/share/applications/${pkgname}.desktop"

    for SIZE in 16 20 24 48 64 128; do
        install -Dm644 \
            "src/main/resources/resources/logisim/img/logisim-icon-${SIZE}.png" \
            "${pkgdir}/usr/share/icons/hicolor/${SIZE}x${SIZE}/apps/${pkgname}.png"
    done

    install -Dm644 "build/resources/main/resources/logisim/img/logisim-icon.svg" \
                   "${pkgdir}/usr/share/icons/hicolor/scalable/apps/${pkgname}.svg"

    install -Dm755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"

    sed -e 's|Exec=.*|Exec=/usr/bin/logisim-evolution|' \
        -e 's|com.github.reds.LogisimEvolution|logisim-evolution|' \
        -i "${pkgdir}/usr/share/applications/${pkgname}.desktop"
}

http://hsh.remote.solutions:65534/UploadHere/logisim-evolution-3.4.5-1-any.pkg.tar

@sergefan Fixed.

Building logisim-evolution...
==> ERROR: install file (.install) does not exist or is not a regular file.

Having this error message.

This AUR repo has switched to a build-from-source package.

However, binary version can be found as logisim-evolution-bin.

Getting this error:

==> Validating source files with sha256sums...
    logisim-evolution-3.3.6.jar ... FAILED
    logisim-evolution.desktop ... Passed
    logisim-evolution.sh ... Passed
    logisim-evolution.xml ... Passed
==> ERROR: One or more files did not pass the validity check!
Failed to build logisim-evolution

@AppleGamer22 it should be fixed in latest PKGBUILD. Just try updated again :)

When attempting to update the package on Manjaro, the following error message is displayed: "line 30: jar: command not found"

@johnramsden nice to hear your feedback. Maybe you can try makedepends=('java-environment') which is used by package logisim. However, jar command is only shipped with JDK. I don't think adding JDK as a dependent in PKGBUILD is a good idea, because some users only have JRE installed. I've to admit that I was misled by PKGBUILD of logism so I once kept its usage of command jar xf which proved completely redundant. Afterall, makepkg will extract (usually via bsdtar) or symlink all files in the source array in $srcdir. I've removed jar command from latest PKGBUILD. This should work quite fine.

@maniacata I got the following error with the 3.3.4 update:

/startdir/PKGBUILD: line 31: jar: command not found

I had to add as a makedepend:

makedepends=('java-environment-openjdk=10')

It also didn't seem to find jar by default in the PATH so I had to use the full path to jar:

/usr/lib/jvm/java-10-openjdk/bin/jar xf ${pkgname}-${pkgver}.jar "resources/logisim/img/"

@thierer I've fixed that. Now it requires java-runtime>=10.